X-Git-Url: https://git.ucc.asn.au/?a=blobdiff_plain;f=KernelLand%2FKernel%2Farch%2Farmv7%2Flink.ld;fp=KernelLand%2FKernel%2Farch%2Farmv7%2Flink.ld;h=d10dcc4645f2a9824b93c764177830d06abde2c2;hb=48743e39650eb1ef988380e9d95f27fd40d3a9ce;hp=0000000000000000000000000000000000000000;hpb=a2495c6ea4f4cab16b5d339ae511428e92e89e73;p=tpg%2Facess2.git

diff --git a/KernelLand/Kernel/arch/armv7/link.ld b/KernelLand/Kernel/arch/armv7/link.ld
new file mode 100644
index 00000000..d10dcc46
--- /dev/null
+++ b/KernelLand/Kernel/arch/armv7/link.ld
@@ -0,0 +1,55 @@
+ENTRY (_start)
+
+_kernel_base = 0x80000000;
+_usertext_vbase = 0xFFFFE000;
+
+SECTIONS
+{
+	. = 0;
+	.init :
+	{
+		*(.init)
+	}
+	. += _kernel_base;
+	.text : AT( ADDR(.text) - _kernel_base )
+	{
+		*(.text*)
+		*(.rodata*)
+	}
+			
+
+	/* HACKS: User accesible .text section */
+	. = ALIGN(0x1000);
+	gUsertextPhysStart = . - _kernel_base;
+	. = _usertext_vbase;
+	.usertext : AT( gUsertextPhysStart )
+	{
+		*(.usertext)
+	}
+	. += gUsertextPhysStart + _kernel_base - _usertext_vbase;
+	
+	/* 0x4000 (4 pages) alignment needed for root table */
+	.data ALIGN(0x4000) : AT( ADDR(.data) - _kernel_base )
+	{
+		*(.padata)
+		*(.data*)
+		
+		gKernelSymbols = .;
+		*(KEXPORT)
+		gKernelSymbolsEnd = .;
+		
+		gKernelModules = .;
+		*(KMODULES)
+		gKernelModulesEnd = .;
+	}
+	.bss : AT( ADDR(.bss) - _kernel_base )
+	{
+		bss_start = .;
+		*(.bss*)
+		*(COMMON*)
+		. = ALIGN(0x1000);
+		*(.pabss)
+		bss_end = .;
+	}
+	gKernelEnd = .;
+}