Kernel/arch/armv7/start.S

   1
   2 #include "include/assembly.h"
   3 #include "include/options.h"
   4
   5 @
   6 @ Exception defs taken from ARM DDI 0406B
   7 @
   8 .section .init
   9 interrupt_vector_table:
  10 ivt_reset:      b _start @ Reset
  11 ivt_undef:      b .     @ #UD
  12 ivt_svc:        b SVC_Handler @ SVC (used to be called SWI)
  13 ivt_prefetch:   b PrefetchAbort @ Prefetch abort
  14 ivt_data:       b DataAbort     @ Data abort
  15 ivt_unused:     b .     @ Not Used
  16 ivt_irq:        b IRQHandler    @ IRQ
  17 ivt_fiq:        b .     @ FIQ (Fast interrupt)
  18
  19 .globl _start
  20 _start:
  21         ldr r0, =kernel_table0-KERNEL_BASE
  22         mcr p15, 0, r0, c2, c0, 1       @ Set TTBR1 to r0
  23         mcr p15, 0, r0, c2, c0, 0       @ Set TTBR0 to r0 too (for identity)
  24
  25         mov r0, #1
  26         mcr p15, 0, r0, c2, c0, 2       @ Set TTCR to 1 (50/50 split)
  27
  28         mov r0, #3
  29         mcr p15, 0, r0, c3, c0, 0       @ Set Domain 0 to Manager
  30
  31         @ Enable VMSA
  32         mrc p15, 0, r0, c1, c0, 0
  33         orr r0, r0, #1
  34         orr r0, r0, #1 << 23
  35         mcr p15, 0, r0, c1, c0, 0
  36
  37         @
  38         @ Check for security extensions
  39         @
  40         mrc p15, 0, r0, c0, c1, 1
  41         and r0, #0xF0
  42         @ - Present
  43         ldrne r0,=KERNEL_BASE
  44         mcrne p15, 0, r0, c12, c0, 0    @ Set the VBAR (brings exceptions into high memory)
  45         @ - Absent
  46         mrceq p15, 0, r0, c1, c0, 0     @ Set SCTLR.V
  47         orreq r0, #0x2000
  48         mcreq p15, 0, r0, c1, c0, 0
  49
  50
  51         @ Prepare for interrupts
  52         cps #18 @ IRQ Mode
  53         ldr sp, =irqstack+0x1000        @ Set up stack
  54         cps #23 @ Abort Mode
  55         ldr sp, =abortstack+0x1000
  56         cps #19
  57
  58         ldr sp, =0x80000000-4   @ Set up stack (top of user range)
  59         ldr r0, =kmain
  60         mov pc, r0
  61 1:      b 1b    @ Infinite loop
  62 _ptr_kmain:
  63         .long kmain
  64
  65 .comm irqstack, 0x1000  @ ; 4KiB Stack
  66 .comm abortstack, 0x1000        @ ; 4KiB Stack
  67
  68 .extern SyscallHandler
  69 SVC_Handler:
  70 @       sub lr, #4
  71         srsdb sp!, #19  @ Save state to stack
  72         cpsie ifa, #19  @ Ensure we're in supervisor with interrupts enabled (should already be there)
  73         push {r0-r12}
  74
  75         ldr r4, [lr,#-4]
  76         mvn r5, #0xFF000000
  77         and r4, r5
  78
  79         tst r4, #0x1000
  80         bne .arm_specifics
  81
  82         push {r4}
  83
  84         mov r0, sp
  85         ldr r4, =SyscallHandler
  86         blx r4
  87
  88         pop {r2}        @ errno
  89         pop {r0,r1}     @ Ret/RetHi
  90         add sp, #2*4    @ Saved r2/r3
  91
  92         pop {r4-r12}
  93         rfeia sp!       @ Pop state (actually RFEFD)
  94 .arm_specifics:
  95         and r4, #0xFF
  96         mov r0, r4      @ Number
  97         mov r1, sp      @ Arguments
  98
  99         ldr r4, =ARMv7_int_HandleSyscalls
 100         blx r4
 101
 102         add sp, #4*4
 103         pop {r4-r12}
 104         rfeia sp!
 105
 106
 107 .globl gpIRQHandler
 108 gpIRQHandler:   .long   0
 109 IRQ_saved_sp:   .long   0
 110 IRQ_saved_lr:   .long   0
 111 .globl IRQHandler
 112 IRQHandler:
 113         sub lr, #4      @ Adjust LR to the correct value
 114         srsdb sp!, #19  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 115         cps #19
 116
 117         PUSH_GPRS
 118
 119 @       ldr r0, =csIRQ_Tag
 120 @       ldr r1, =csIRQ_Fmt
 121 @       ldr r4, =Log_Debug
 122 @       blx r4
 123
 124         @ Call the registered handler
 125         ldr r0, gpIRQHandler
 126         blx r0
 127
 128         @ Restore CPU state
 129         POP_GPRS
 130         cpsie i
 131         rfeia sp!       @ Pop state (actually RFEFD)
 132         bx lr
 133
 134 .globl DataAbort
 135 DataAbort:
 136         sub lr, #8      @ Adjust LR to the correct value
 137 @       srsdb sp!, #19  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 138 @       cpsid ifa, #19
 139 @       PUSH_GPRS
 140
 141         mrc p15, 0, r4, c5, c0, 0       @ Read DFSR (Data Fault Address Register) to stack
 142         push {r4}
 143         mrc p15, 0, r3, c6, c0, 0       @ Read DFAR (Data Fault Address Register) into R3
 144         mov r2, lr
 145         ldr r1, =csDataAbort_Fmt
 146         ldr r0, =csAbort_Tag
 147         ldr r4, =Log_Error
 148         blx r4
 149         b .
 150
 151 @       POP_GPRS
 152 @       rfeia sp!       @ Pop state (actually RFEFD)
 153
 154 .globl PrefetchAbort
 155 PrefetchAbort:
 156         sub lr, #4      @ Adjust LR to the correct value
 157 @       srsdb sp!, #19  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 158 @       cpsid ifa, #19
 159 @       PUSH_GPRS
 160
 161         ldr r0, =csAbort_Tag
 162         ldr r1, =csPrefetchAbort_Fmt
 163         mov r2, lr
 164         mrc p15, 0, r3, c5, c0, 0       @ Read IFSR (Instruction Fault Address Register) into R3
 165         ldr r4, =Log_Error
 166         blx r4
 167         b .
 168
 169 csIRQ_Tag:
 170 csAbort_Tag:
 171         .asciz "ARMv7"
 172 csIRQ_Fmt:
 173         .asciz "IRQ"
 174 csDataAbort_Fmt:
 175         .asciz "Data Abort - %p accessed %p, DFSR=%x Unk:%x Unk:%x"
 176 csPrefetchAbort_Fmt:
 177         .asciz "Prefetch Abort at %p, IFSR=%x"
 178
 179 .section .padata
 180 .globl kernel_table0
 181
 182 kernel_table0:
 183         .long 0x00000002        @ Identity map the first 1 MiB
 184         .rept 0x7FC - 1
 185                 .long 0
 186         .endr
 187         .long user_table1_map + 0x000 - KERNEL_BASE + 1 @ 0x7FC00000
 188         .long user_table1_map + 0x400 - KERNEL_BASE + 1 @ 0x7FD00000
 189         .long user_table1_map + 0x800 - KERNEL_BASE + 1 @ KStacks
 190         .long user_table1_map + 0xC00 - KERNEL_BASE + 1
 191         @ 0x80000000 - User/Kernel split
 192         .long 0x00000002        @ Map first 4 MiB to 2GiB
 193         .long 0x00100002        @
 194         .long 0x00200002        @
 195         .long 0x00300002        @
 196         .rept 0xF00 - 0x800 - 4
 197                 .long 0
 198         .endr
 199 #if PCI_PADDR
 200         .long PCI_PADDR +  0*(1 << 20) + 2      @ Map PCI config space
 201         .long PCI_PADDR +  1*(1 << 20) + 2
 202         .long PCI_PADDR +  2*(1 << 20) + 2
 203         .long PCI_PADDR +  3*(1 << 20) + 2
 204         .long PCI_PADDR +  4*(1 << 20) + 2
 205         .long PCI_PADDR +  5*(1 << 20) + 2
 206         .long PCI_PADDR +  6*(1 << 20) + 2
 207         .long PCI_PADDR +  7*(1 << 20) + 2
 208         .long PCI_PADDR +  8*(1 << 20) + 2
 209         .long PCI_PADDR +  9*(1 << 20) + 2
 210         .long PCI_PADDR + 10*(1 << 20) + 2
 211         .long PCI_PADDR + 11*(1 << 20) + 2
 212         .long PCI_PADDR + 12*(1 << 20) + 2
 213         .long PCI_PADDR + 13*(1 << 20) + 2
 214         .long PCI_PADDR + 14*(1 << 20) + 2
 215         .long PCI_PADDR + 15*(1 << 20) + 2
 216 #else
 217         .rept 16
 218                 .long 0
 219         .endr
 220 #endif
 221         .long hwmap_table_0 + 0x000 - KERNEL_BASE + 1
 222         .long hwmap_table_0 + 0x400 - KERNEL_BASE + 1
 223         .long hwmap_table_0 + 0x800 - KERNEL_BASE + 1
 224         .long hwmap_table_0 + 0xC00 - KERNEL_BASE + 1
 225         .rept 0xFF8 - 0xF00 - 16 - 4
 226                 .long 0
 227         .endr
 228         @ Page fractals
 229         .long kernel_table1_map + 0x000 - KERNEL_BASE + 1
 230         .long kernel_table1_map + 0x400 - KERNEL_BASE + 1
 231         .long kernel_table1_map + 0x800 - KERNEL_BASE + 1
 232         .long kernel_table1_map + 0xC00 - KERNEL_BASE + 1
 233         .long kernel_exception_map + 0x000 - KERNEL_BASE + 1
 234         .long kernel_exception_map + 0x400 - KERNEL_BASE + 1
 235         .long kernel_exception_map + 0x800 - KERNEL_BASE + 1
 236         .long kernel_exception_map + 0xC00 - KERNEL_BASE + 1
 237
 238 @ PID0 user table
 239 .globl user_table1_map
 240 @ User table1 data table (only the first half is needed)
 241 @ - Abused to provide kernel stacks in upper half
 242 user_table1_map:        @ Size = 4KiB (only 2KiB used)
 243         .rept 0x800/4-1
 244                 .long 0
 245         .endr
 246         .long user_table1_map - KERNEL_BASE + 0x10 + 3          @ ...1FF000 = 0x7FDFF000
 247         @ Kernel stack zone
 248         .long kernel_table0 + 0x0000 - KERNEL_BASE + 0x10 + 3   @ ...200000 = 0x7FE00000
 249         .long kernel_table0 + 0x1000 - KERNEL_BASE + 0x10 + 3   @ ...201000 = 0x7FE01000
 250         .rept (0x800/4)-(MM_KSTACK_SIZE/0x1000)-2
 251                 .long 0
 252         .endr
 253         #if MM_KSTACK_SIZE != 0x2000
 254         #error Kernel stack size not changed in start.S
 255         #endif
 256         .long stack + 0x0000 - KERNEL_BASE + 0x10 + 3   @ Kernel Stack
 257         .long stack + 0x1000 - KERNEL_BASE + 0x10 + 3   @
 258
 259 .globl kernel_table1_map
 260 kernel_table1_map:      @ Size = 4KiB
 261         .rept (0xF00+16)/4
 262                 .long 0
 263         .endr
 264         .long hwmap_table_0 - KERNEL_BASE + (1 << 4) + 3
 265         .rept 0xFF8/4 - (0xF00+16)/4 - 1
 266                 .long 0
 267         .endr
 268         .long kernel_table1_map - KERNEL_BASE + (1 << 4) + 3
 269         .long kernel_exception_map - KERNEL_BASE + 0x13
 270
 271 @ Hardware mappings
 272 .globl hwmap_table_0
 273 hwmap_table_0:
 274         .long UART0_PADDR + (1 << 4) + 3        @ UART0
 275         .rept 1024 - 1
 276                 .long 0
 277         .endr
 278 .globl kernel_exception_map
 279 kernel_exception_map:
 280         @ Padding
 281         .rept 1024-256
 282                 .long 0
 283         .endr
 284         @ Align to nearly the end
 285         .rept 256-16
 286                 .long   0
 287         .endr
 288         .long 0x213     @ Map first page for exceptions (Kernel RO)
 289         .rept 15
 290                 .long 0
 291         .endr
 292
 293 .section .padata
 294 stack:
 295         .space MM_KSTACK_SIZE, 0        @ Original kernel stack
 296