Kernel/arch/armv7/start.S

   1
   2 #include "include/assembly.h"
   3 #include "include/options.h"
   4
   5 @
   6 @ Exception defs taken from ARM DDI 0406B
   7 @
   8 .section .init
   9 interrupt_vector_table:
  10 ivt_reset:      b _start @ Reset
  11 ivt_undef:      b .     @ #UD
  12 ivt_svc:        b SVC_Handler @ SVC (used to be called SWI)
  13 ivt_prefetch:   b PrefetchAbort @ Prefetch abort
  14 ivt_data:       b DataAbort     @ Data abort
  15 ivt_unused:     b .     @ Not Used
  16 ivt_irq:        b IRQHandler    @ IRQ
  17 ivt_fiq:        b .     @ FIQ (Fast interrupt)
  18
  19 .globl _start
  20 _start:
  21         ldr r0, =kernel_table0-KERNEL_BASE
  22         mcr p15, 0, r0, c2, c0, 1       @ Set TTBR1 to r0
  23         mcr p15, 0, r0, c2, c0, 0       @ Set TTBR0 to r0 too (for identity)
  24
  25         mov r0, #1
  26         mcr p15, 0, r0, c2, c0, 2       @ Set TTCR to 1 (50/50 split)
  27
  28         mov r0, #3
  29         mcr p15, 0, r0, c3, c0, 0       @ Set Domain 0 to Manager
  30
  31         @ Enable VMSA
  32         mrc p15, 0, r0, c1, c0, 0
  33         orr r0, r0, #1
  34         orr r0, r0, #1 << 23
  35         mcr p15, 0, r0, c1, c0, 0
  36
  37         @
  38         @ Check for security extensions
  39         @
  40         mrc p15, 0, r0, c0, c1, 1
  41         and r0, #0xF0
  42         @ - Present
  43         ldrne r0,=KERNEL_BASE
  44         mcrne p15, 0, r0, c12, c0, 0    @ Set the VBAR (brings exceptions into high memory)
  45         @ - Absent
  46         mrceq p15, 0, r0, c1, c0, 0     @ Set SCTLR.V
  47         orreq r0, #0x2000
  48         mcreq p15, 0, r0, c1, c0, 0
  49
  50
  51         @ Prepare for interrupts
  52         cps #18 @ IRQ Mode
  53         ldr sp, =irqstack+0x1000        @ Set up stack
  54         cps #23 @ Abort Mode
  55         ldr sp, =abortstack+0x1000
  56         cps #19
  57
  58         ldr sp, =0x80000000-4   @ Set up stack (top of user range)
  59         ldr r0, =kmain
  60         mov pc, r0
  61 1:      b 1b    @ Infinite loop
  62 _ptr_kmain:
  63         .long kmain
  64
  65 .comm irqstack, 0x1000  @ ; 4KiB Stack
  66 .comm abortstack, 0x1000        @ ; 4KiB Stack
  67
  68 .extern SyscallHandler
  69 SVC_Handler:
  70 @       sub lr, #4
  71         srsdb sp!, #19  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
  72         cpsid ifa, #19
  73         push {r0-r12}
  74
  75         ldr r4, [lr,#-4]
  76         mvn r5, #0xFF000000
  77         and r4, r5
  78
  79         push {r4}
  80
  81         mov r0, sp
  82         ldr r4, =SyscallHandler
  83         blx r4
  84
  85         pop {r2}        @ errno
  86         pop {r0,r1}     @ Ret/RetHi
  87         add sp, #2*4    @ Saved r2/r3
  88
  89         pop {r4-r12}
  90         rfeia sp!       @ Pop state (actually RFEFD)
  91
  92 .globl gpIRQHandler
  93 gpIRQHandler:   .long   0
  94 IRQ_saved_sp:   .long   0
  95 IRQ_saved_lr:   .long   0
  96 .globl IRQHandler
  97 IRQHandler:
  98         sub lr, #4      @ Adjust LR to the correct value
  99         srsdb sp!, #19  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 100         cps #19
 101
 102         PUSH_GPRS
 103
 104 @       ldr r0, =csIRQ_Tag
 105 @       ldr r1, =csIRQ_Fmt
 106 @       ldr r4, =Log_Debug
 107 @       blx r4
 108
 109         @ Call the registered handler
 110         ldr r0, gpIRQHandler
 111         blx r0
 112
 113         @ Restore CPU state
 114         POP_GPRS
 115         cpsie i
 116         rfeia sp!       @ Pop state (actually RFEFD)
 117         bx lr
 118
 119 .globl DataAbort
 120 DataAbort:
 121         sub lr, #8      @ Adjust LR to the correct value
 122 @       srsdb sp!, #19  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 123 @       cpsid ifa, #19
 124 @       PUSH_GPRS
 125
 126         mrc p15, 0, r4, c5, c0, 0       @ Read DFSR (Data Fault Address Register) to stack
 127         push {r4}
 128         mrc p15, 0, r3, c6, c0, 0       @ Read DFAR (Data Fault Address Register) into R3
 129         mov r2, lr
 130         ldr r1, =csDataAbort_Fmt
 131         ldr r0, =csAbort_Tag
 132         ldr r4, =Log_Error
 133         blx r4
 134         b .
 135
 136 @       POP_GPRS
 137 @       rfeia sp!       @ Pop state (actually RFEFD)
 138         bx lr
 139
 140 .globl PrefetchAbort
 141 PrefetchAbort:
 142         sub lr, #4      @ Adjust LR to the correct value
 143 @       srsdb sp!, #19  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 144 @       cpsid ifa, #19
 145 @       PUSH_GPRS
 146
 147         ldr r0, =csAbort_Tag
 148         ldr r1, =csPrefetchAbort_Fmt
 149         mov r2, lr
 150         mrc p15, 0, r3, c5, c0, 0       @ Read IFSR (Instruction Fault Address Register) into R3
 151         ldr r4, =Log_Error
 152         blx r4
 153         b .
 154
 155 csIRQ_Tag:
 156 csAbort_Tag:
 157         .asciz "ARMv7"
 158 csIRQ_Fmt:
 159         .asciz "IRQ"
 160 csDataAbort_Fmt:
 161         .asciz "Data Abort - %p accessed %p, DFSR=%x Unk:%x Unk:%x"
 162 csPrefetchAbort_Fmt:
 163         .asciz "Prefetch Abort at %p, IFSR=%x"
 164
 165 .section .padata
 166 .globl kernel_table0
 167
 168 kernel_table0:
 169         .long 0x00000002        @ Identity map the first 1 MiB
 170         .rept 0x7FC - 1
 171                 .long 0
 172         .endr
 173         .long user_table1_map + 0x000 - KERNEL_BASE + 1 @ 0x7FC00000
 174         .long user_table1_map + 0x400 - KERNEL_BASE + 1 @ 0x7FD00000
 175         .long user_table1_map + 0x800 - KERNEL_BASE + 1 @ KStacks
 176         .long user_table1_map + 0xC00 - KERNEL_BASE + 1
 177         @ 0x80000000 - User/Kernel split
 178         .long 0x00000002        @ Map first 4 MiB to 2GiB
 179         .long 0x00100002        @
 180         .long 0x00200002        @
 181         .long 0x00300002        @
 182         .rept 0xF00 - 0x800 - 4
 183                 .long 0
 184         .endr
 185 #if PCI_PADDR
 186         .long PCI_PADDR +  0*(1 << 20) + 2      @ Map PCI config space
 187         .long PCI_PADDR +  1*(1 << 20) + 2
 188         .long PCI_PADDR +  2*(1 << 20) + 2
 189         .long PCI_PADDR +  3*(1 << 20) + 2
 190         .long PCI_PADDR +  4*(1 << 20) + 2
 191         .long PCI_PADDR +  5*(1 << 20) + 2
 192         .long PCI_PADDR +  6*(1 << 20) + 2
 193         .long PCI_PADDR +  7*(1 << 20) + 2
 194         .long PCI_PADDR +  8*(1 << 20) + 2
 195         .long PCI_PADDR +  9*(1 << 20) + 2
 196         .long PCI_PADDR + 10*(1 << 20) + 2
 197         .long PCI_PADDR + 11*(1 << 20) + 2
 198         .long PCI_PADDR + 12*(1 << 20) + 2
 199         .long PCI_PADDR + 13*(1 << 20) + 2
 200         .long PCI_PADDR + 14*(1 << 20) + 2
 201         .long PCI_PADDR + 15*(1 << 20) + 2
 202 #else
 203         .rept 16
 204                 .long 0
 205         .endr
 206 #endif
 207         .long hwmap_table_0 + 0x000 - KERNEL_BASE + 1
 208         .long hwmap_table_0 + 0x400 - KERNEL_BASE + 1
 209         .long hwmap_table_0 + 0x800 - KERNEL_BASE + 1
 210         .long hwmap_table_0 + 0xC00 - KERNEL_BASE + 1
 211         .rept 0xFF8 - 0xF00 - 16 - 4
 212                 .long 0
 213         .endr
 214         @ Page fractals
 215         .long kernel_table1_map + 0x000 - KERNEL_BASE + 1
 216         .long kernel_table1_map + 0x400 - KERNEL_BASE + 1
 217         .long kernel_table1_map + 0x800 - KERNEL_BASE + 1
 218         .long kernel_table1_map + 0xC00 - KERNEL_BASE + 1
 219         .long kernel_exception_map + 0x000 - KERNEL_BASE + 1
 220         .long kernel_exception_map + 0x400 - KERNEL_BASE + 1
 221         .long kernel_exception_map + 0x800 - KERNEL_BASE + 1
 222         .long kernel_exception_map + 0xC00 - KERNEL_BASE + 1
 223
 224 @ PID0 user table
 225 .globl user_table1_map
 226 @ User table1 data table (only the first half is needed)
 227 @ - Abused to provide kernel stacks in upper half
 228 user_table1_map:        @ Size = 4KiB (only 2KiB used)
 229         .rept 0x800/4-1
 230                 .long 0
 231         .endr
 232         .long user_table1_map - KERNEL_BASE + 0x10 + 3          @ ...1FF000 = 0x7FDFF000
 233         @ Kernel stack zone
 234         .long kernel_table0 + 0x0000 - KERNEL_BASE + 0x10 + 3   @ ...200000 = 0x7FE00000
 235         .long kernel_table0 + 0x1000 - KERNEL_BASE + 0x10 + 3   @ ...201000 = 0x7FE01000
 236         .rept (0x800/4)-(MM_KSTACK_SIZE/0x1000)-2
 237                 .long 0
 238         .endr
 239         #if MM_KSTACK_SIZE != 0x2000
 240         #error Kernel stack size not changed in start.S
 241         #endif
 242         .long stack + 0x0000 - KERNEL_BASE + 0x10 + 3   @ Kernel Stack
 243         .long stack + 0x1000 - KERNEL_BASE + 0x10 + 3   @
 244
 245 .globl kernel_table1_map
 246 kernel_table1_map:      @ Size = 4KiB
 247         .rept (0xF00+16)/4
 248                 .long 0
 249         .endr
 250         .long hwmap_table_0 - KERNEL_BASE + (1 << 4) + 3
 251         .rept 0xFF8/4 - (0xF00+16)/4 - 1
 252                 .long 0
 253         .endr
 254         .long kernel_table1_map - KERNEL_BASE + (1 << 4) + 3
 255         .long kernel_exception_map - KERNEL_BASE + 0x13
 256
 257 @ Hardware mappings
 258 .globl hwmap_table_0
 259 hwmap_table_0:
 260         .long UART0_PADDR + (1 << 4) + 3        @ UART0
 261         .rept 1024 - 1
 262                 .long 0
 263         .endr
 264 .globl kernel_exception_map
 265 kernel_exception_map:
 266         @ Padding
 267         .rept 1024-256
 268                 .long 0
 269         .endr
 270         @ Align to nearly the end
 271         .rept 256-16
 272                 .long   0
 273         .endr
 274         .long 0x213     @ Map first page for exceptions (Kernel RO)
 275         .rept 15
 276                 .long 0
 277         .endr
 278
 279 .section .padata
 280 stack:
 281         .space MM_KSTACK_SIZE, 0        @ Original kernel stack
 282