Kernel/arch/x86/link.ld

   1 /*
   2  * AcessMicro Kernel
   3  * Linker Script
   4  */
   5
   6 lowStart = start - 0xC0000000;
   7 ENTRY(lowStart)
   8 OUTPUT_FORMAT(elf32-i386)
   9
  10 SECTIONS {
  11         . = 0x100000;
  12         .multiboot : AT(ADDR(.multiboot)) {
  13                 *(.multiboot)
  14         }
  15
  16         . += 0xC0000000;
  17
  18         .text ALIGN(0x1000): AT(ADDR(.text) - 0xC0000000) {
  19                 *(.text)
  20         }
  21
  22         .usertext ALIGN(0x1000): AT(ADDR(.usertext) - 0xC0000000) {
  23                 _UsertextBase = .;
  24                 *(.usertext)
  25         }
  26
  27         .rodata ALIGN(0x1000): AT(ADDR(.rodata) - 0xC0000000) {
  28                 *(.initpd)
  29                 *(.rodata)
  30                 *(.rdata)
  31                 _gKernelModules = .;
  32                 *(KMODULES)
  33                 _gKernelModulesEnd = .;
  34                 . = ALIGN(4);
  35                 _gKernelSymbols = .;
  36                 *(KEXPORT)
  37                 _gKernelSymbolsEnd = .;
  38
  39         }
  40
  41         .padata ALIGN (0x1000) : AT(ADDR(.padata) - 0xC0000000) {
  42                 *(.padata)
  43         }
  44
  45         .data ALIGN (0x1000) : AT(ADDR(.data) - 0xC0000000) {
  46                 *(.data)
  47         }
  48
  49         .bss : AT(ADDR(.bss) - 0xC0000000) {
  50                 _sbss = .;
  51                 *(COMMON)
  52                 *(.bss)
  53                 _ebss = .;
  54         }
  55         _gKernelEnd = (. + 0xFFF)&0xFFFFF000;
  56 }