Kernel/arch/x86/start.asm

   1 ; AcessOS Microkernel Version
   2 ; Start.asm
   3
   4 [bits 32]
   5
   6 KERNEL_BASE     equ 0xC0000000
   7 %define MAX_CPUS        16
   8
   9 [extern __load_addr]
  10 [extern __bss_start]
  11 [extern gKernelEnd]
  12 [section .multiboot]
  13 mboot:
  14         ; Multiboot macros to make a few lines later more readable
  15         MULTIBOOT_PAGE_ALIGN    equ 1<<0
  16         MULTIBOOT_MEMORY_INFO   equ 1<<1
  17         MULTIBOOT_HEADER_MAGIC  equ 0x1BADB002
  18         MULTIBOOT_HEADER_FLAGS  equ MULTIBOOT_PAGE_ALIGN | MULTIBOOT_MEMORY_INFO
  19         MULTIBOOT_CHECKSUM      equ -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)
  20
  21         ; This is the GRUB Multiboot header. A boot signature
  22         dd MULTIBOOT_HEADER_MAGIC
  23         dd MULTIBOOT_HEADER_FLAGS
  24         dd MULTIBOOT_CHECKSUM
  25         dd mboot; - KERNEL_BASE ;Location of Multiboot Header
  26
  27 ; Multiboot 2 Header
  28 ;mboot2:
  29 ;       MULTIBOOT2_HEADER_MAGIC equ 0xE85250D6
  30 ;       MULTIBOOT2_HEADER_ARCH  equ 0
  31 ;       MULTIBOOT2_HEADER_LENGTH        equ (mboot2_end-mboot2)
  32 ;       MULTIBOOT2_CHECKSUM     equ -(MULTIBOOT2_HEADER_MAGIC + MULTIBOOT2_HEADER_ARCH + MULTIBOOT2_HEADER_LENGTH)
  33 ;
  34 ;       dd MULTIBOOT2_HEADER_MAGIC
  35 ;       dd MULTIBOOT2_HEADER_ARCH
  36 ;       dd MULTIBOOT2_HEADER_LENGTH
  37 ;       dd MULTIBOOT2_CHECKSUM
  38 ;       ; MBoot2 Address Header
  39 ;       dw      2, 0
  40 ;       dd      8 + 16
  41 ;       dd      mboot2  ; Location of Multiboot Header
  42 ;       dd      __load_addr - KERNEL_BASE       ; Kernel Load base
  43 ;       dd      __bss_start - KERNEL_BASE       ; Kernel Data End
  44 ;       dd      gKernelEnd - KERNEL_BASE        ; Kernel BSS End
  45 ;       ; MBoot2 Entry Point Tag
  46 ;       dw      3, 0
  47 ;       dd      8 + 4
  48 ;       dd      start - KERNEL_BASE
  49 ;       ; MBoot2 Module Alignment Tag
  50 ;       dw      6, 0
  51 ;       dd      12      ; ???
  52 ;       dd      0       ; Search me, seems it wants padding
  53 ;       ; Terminator
  54 ;       dw      0, 0
  55 ;       dd      8
  56 ;mboot2_end:
  57
  58 [section .text]
  59 [extern kmain]
  60 [global start]
  61 start:
  62         ; Just show we're here
  63         mov WORD [0xB8000], 0x0741      ; 'A'
  64
  65         ; Set up stack
  66         mov esp, Kernel_Stack_Top
  67
  68         ; Start Paging
  69         mov ecx, gaInitPageDir - KERNEL_BASE
  70         mov cr3, ecx
  71
  72         mov ecx, cr0
  73         or      ecx, 0x80010000 ; PG and WP
  74         mov cr0, ecx
  75
  76         mov WORD [0xB8002], 0x0763      ; 'c'
  77         mov WORD [0xB8004], 0x0765      ; 'e'
  78
  79         lea ecx, [.higherHalf]
  80         jmp ecx
  81 .higherHalf:
  82
  83         mov WORD [0xB8006], 0x0773      ; 's'
  84         mov WORD [0xB8008], 0x0773      ; 's'
  85
  86         ; Call the kernel
  87         push ebx        ; Multiboot Info
  88         push eax        ; Multiboot Magic Value
  89         mov WORD [0xB800A], 0x0732      ; '2'
  90         call kmain
  91
  92         ; Halt the Machine
  93         cli
  94 .hlt:
  95         hlt
  96         jmp .hlt
  97
  98 ;
  99 ; Multiprocessing AP Startup Code (Must be within 0x10FFF0)
 100 ;
 101 %if USE_MP
 102 [extern gGDT]
 103 [extern gGDTPtr]
 104 [extern gIDTPtr]
 105 [extern gpMP_LocalAPIC]
 106 [extern giMP_TimerCount]
 107 [extern gaAPIC_to_CPU]
 108 [extern gaCPUs]
 109 [extern giNumInitingCPUs]
 110 [extern MM_NewKStack]
 111
 112 lGDTPtr:        ; Local GDT Pointer
 113         dw      3*8-1
 114         dd      gGDT-KERNEL_BASE
 115
 116 [bits 16]
 117 [global APWait]
 118 APWait:
 119         ;xchg bx, bx
 120 .hlt:
 121         ;hlt
 122         jmp .hlt
 123 [global APStartup]
 124 APStartup:
 125         ;xchg bx, bx    ; MAGIC BREAK!
 126         mov ax, 0xFFFF
 127         mov ds, ax
 128         lgdt [DWORD ds:lGDTPtr-KERNEL_BASE-0xFFFF0]
 129         mov eax, cr0
 130         or al, 1
 131         mov cr0, eax
 132         jmp 08h:DWORD .ProtectedMode-KERNEL_BASE
 133 [bits 32]
 134 .ProtectedMode:
 135         ; Load segment registers
 136         mov ax, 0x10
 137         mov ss, ax
 138         mov ds, ax
 139         mov es, ax
 140         mov fs, ax
 141         mov gs, ax
 142         ; Start Paging
 143         mov eax, gaInitPageDir - KERNEL_BASE
 144         mov cr3, eax
 145         mov eax, cr0
 146         or eax, 0x80010000      ; PG and WP
 147         mov cr0, eax
 148         ; Jump to higher half
 149         lea eax, [.higherHalf]
 150         jmp eax
 151 .higherHalf:
 152         ; Load True GDT & IDT
 153         lgdt [gGDTPtr]
 154         lidt [gIDTPtr]
 155
 156         mov ebp, [gpMP_LocalAPIC]
 157         mov ebx, [ebp+0x20]     ; Read ID
 158         shr ebx, 24
 159         ;xchg bx, bx    ; MAGIC BREAK
 160         ; CL is now local APIC ID
 161         mov cl, BYTE [gaAPIC_to_CPU+ebx]
 162         xor ebx, ebx
 163         mov bl, cl
 164         ; BL is now the CPU ID
 165         mov BYTE [gaCPUs+ebx*8+1], 1
 166         ; Decrement the remaining CPU count
 167         dec DWORD [giNumInitingCPUs]
 168
 169         ; Create a stack
 170         lea edx, [ebx+1]
 171         shl edx, 5+2    ; *32 *4
 172         lea esp, [gInitAPStacks+edx]
 173         call MM_NewKStack
 174         mov esp, eax
 175
 176         ; Set TSS
 177         lea ecx, [ebx*8+0x30]
 178         ltr cx
 179         ; Save the CPU number to a debug register
 180         mov dr1, ebx
 181
 182         ;xchg bx, bx    ; MAGIC_BREAK
 183         ; Enable Local APIC
 184         mov DWORD [ebp+0x0F0], 0x000001EF       ; Spurious Interrupt Vector (0xEF)
 185         mov ecx, DWORD [giMP_TimerCount]
 186         mov DWORD [ebp+0x380], ecx      ; Set Initial Count
 187         mov DWORD [ebp+0x320], 0x000200EE       ; Enable timer on IVT#0xEE
 188         mov DWORD [ebp+0x330], 0x000100E0       ; ##Enable thermal sensor on IVT#0xE0
 189         mov DWORD [ebp+0x340], 0x000100D0       ; ##Enable performance counters on IVT#0xD0
 190         mov DWORD [ebp+0x350], 0x000100D1       ; ##Enable LINT0 on IVT#0xD1
 191         mov DWORD [ebp+0x360], 0x000100D2       ; ##Enable LINT1 on IVT#0xD2
 192         mov DWORD [ebp+0x370], 0x000100E1       ; ##Enable Error on IVT#0xE1
 193         mov DWORD [ebp+0x0B0], 0        ; Send an EOI (just in case)
 194
 195         ; CPU is now marked as initialised
 196         sti
 197         ;xchg bx, bx    ; MAGIC BREAK
 198 .hlt:
 199         hlt
 200         jmp .hlt
 201 %endif
 202
 203 [global GetEIP]
 204 GetEIP:
 205         mov eax, [esp]
 206         ret
 207
 208 ; int CallWithArgArray(void *Ptr, int NArgs, Uint *Args)
 209 ; Call a function passing the array as arguments
 210 [global CallWithArgArray]
 211 CallWithArgArray:
 212         push ebp
 213         mov ebp, esp
 214         mov ecx, [ebp+12]       ; Get NArgs
 215         mov edx, [ebp+16]
 216
 217 .top:
 218         mov eax, [edx+ecx*4-4]
 219         push eax
 220         loop .top
 221
 222         mov eax, [ebp+8]
 223         call eax
 224         lea esp, [ebp]
 225         pop ebp
 226         ret
 227
 228 [section .initpd]
 229 [global gaInitPageDir]
 230 [global gaInitPageTable]
 231 align 0x1000
 232 gaInitPageDir:
 233         dd      gaInitPageTable-KERNEL_BASE+3   ; 0x000 - Low kernel
 234         times 0x300-0x000-1     dd      0
 235         dd      gaInitPageTable-KERNEL_BASE+3   ; 0xC00 - High kernel
 236         times 0x3F0-0x300-1     dd      0
 237         dd      gaInitPageDir-KERNEL_BASE+3     ; 0xFC0 - Fractal
 238         times 0x400-0x3F0-1     dd      0
 239 align 0x1000
 240 gaInitPageTable:
 241         %assign i 0
 242         %rep 1024
 243         dd      i*0x1000+3
 244         %assign i i+1
 245         %endrep
 246 [global Kernel_Stack_Top]
 247 ALIGN 0x1000
 248         times 1024      dd      0
 249 Kernel_Stack_Top:
 250 gInitAPStacks:
 251         times 32*MAX_CPUS       dd      0
 252