Kernel/arch/x86/start.asm

   1 ; AcessOS Microkernel Version
   2 ; Start.asm
   3
   4 [bits 32]
   5
   6 KERNEL_BASE     equ 0xC0000000
   7 %define MAX_CPUS        16
   8
   9 [extern __load_addr]
  10 [extern __bss_start]
  11 [extern gKernelEnd]
  12 [section .multiboot]
  13 mboot:
  14         ; Multiboot macros to make a few lines later more readable
  15         MULTIBOOT_PAGE_ALIGN    equ 1<<0
  16         MULTIBOOT_MEMORY_INFO   equ 1<<1
  17         MULTIBOOT_HEADER_MAGIC  equ 0x1BADB002
  18         MULTIBOOT_HEADER_FLAGS  equ MULTIBOOT_PAGE_ALIGN | MULTIBOOT_MEMORY_INFO
  19         MULTIBOOT_CHECKSUM      equ -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)
  20
  21         ; This is the GRUB Multiboot header. A boot signature
  22         dd MULTIBOOT_HEADER_MAGIC
  23         dd MULTIBOOT_HEADER_FLAGS
  24         dd MULTIBOOT_CHECKSUM
  25         dd mboot; - KERNEL_BASE ;Location of Multiboot Header
  26
  27 ; Multiboot 2 Header
  28 ;mboot2:
  29 ;       MULTIBOOT2_HEADER_MAGIC equ 0xE85250D6
  30 ;       MULTIBOOT2_HEADER_ARCH  equ 0
  31 ;       MULTIBOOT2_HEADER_LENGTH        equ (mboot2_end-mboot2)
  32 ;       MULTIBOOT2_CHECKSUM     equ -(MULTIBOOT2_HEADER_MAGIC + MULTIBOOT2_HEADER_ARCH + MULTIBOOT2_HEADER_LENGTH)
  33 ;
  34 ;       dd MULTIBOOT2_HEADER_MAGIC
  35 ;       dd MULTIBOOT2_HEADER_ARCH
  36 ;       dd MULTIBOOT2_HEADER_LENGTH
  37 ;       dd MULTIBOOT2_CHECKSUM
  38 ;       ; MBoot2 Address Header
  39 ;       dw      2, 0
  40 ;       dd      8 + 16
  41 ;       dd      mboot2  ; Location of Multiboot Header
  42 ;       dd      __load_addr - KERNEL_BASE       ; Kernel Load base
  43 ;       dd      __bss_start - KERNEL_BASE       ; Kernel Data End
  44 ;       dd      gKernelEnd - KERNEL_BASE        ; Kernel BSS End
  45 ;       ; MBoot2 Entry Point Tag
  46 ;       dw      3, 0
  47 ;       dd      8 + 4
  48 ;       dd      start - KERNEL_BASE
  49 ;       ; MBoot2 Module Alignment Tag
  50 ;       dw      6, 0
  51 ;       dd      12      ; ???
  52 ;       dd      0       ; Search me, seems it wants padding
  53 ;       ; Terminator
  54 ;       dw      0, 0
  55 ;       dd      8
  56 ;mboot2_end:
  57
  58 [section .text]
  59 [extern kmain]
  60 [global start]
  61 start:
  62         ; Just show we're here
  63         mov WORD [0xB8000], 0x0741      ; 'A'
  64
  65         ; Set up stack
  66         mov esp, Kernel_Stack_Top
  67
  68         ; Start Paging
  69         mov ecx, gaInitPageDir - KERNEL_BASE
  70         mov cr3, ecx
  71
  72         mov ecx, cr0
  73         or      ecx, 0x80010000 ; PG and WP
  74         mov cr0, ecx
  75
  76         mov WORD [0xB8002], 0x0763      ; 'c'
  77         mov WORD [0xB8004], 0x0765      ; 'e'
  78
  79         lea ecx, [.higherHalf]
  80         jmp ecx
  81 .higherHalf:
  82
  83         mov WORD [0xB8006], 0x0773      ; 's'
  84         mov WORD [0xB8008], 0x0773      ; 's'
  85
  86         ; Call the kernel
  87         push ebx        ; Multiboot Info
  88         push eax        ; Multiboot Magic Value
  89         mov WORD [0xB800A], 0x0732      ; '2'
  90         call kmain
  91
  92         ; Halt the Machine
  93         cli
  94 .hlt:
  95         hlt
  96         jmp .hlt
  97
  98 ;
  99 ; Multiprocessing AP Startup Code (Must be within 0 - 0x10FFF0)
 100 ;
 101 %if USE_MP
 102 [extern gGDT]
 103 [extern gGDTPtr]
 104 [extern gIDTPtr]
 105 [extern gpMP_LocalAPIC]
 106 [extern giMP_TimerCount]
 107 [extern gaAPIC_to_CPU]
 108 [extern gaCPUs]
 109 [extern giNumInitingCPUs]
 110 [extern MM_NewKStack]
 111
 112 lGDTPtr:        ; Local GDT Pointer
 113         dw      3*8-1
 114         dd      gGDT-KERNEL_BASE
 115
 116 [bits 16]
 117 [global APWait]
 118 APWait:
 119         ;xchg bx, bx
 120 .hlt:
 121         ;hlt
 122         jmp .hlt
 123 [global APStartup]
 124 APStartup:
 125         ;xchg bx, bx    ; MAGIC BREAK!
 126         ; Load initial GDT
 127         mov ax, 0xFFFF
 128         mov ds, ax
 129         lgdt [DWORD ds:lGDTPtr-KERNEL_BASE-0xFFFF0]
 130         ; Enable PMode in CR0
 131         mov eax, cr0
 132         or al, 1
 133         mov cr0, eax
 134         ; Jump into PMode
 135         jmp 08h:DWORD .ProtectedMode-KERNEL_BASE
 136 [bits 32]
 137 .ProtectedMode:
 138         ; Load segment registers
 139         mov ax, 0x10
 140         mov ss, ax
 141         mov ds, ax
 142         mov es, ax
 143         mov fs, ax
 144         mov gs, ax
 145         ; Start Paging
 146         mov eax, gaInitPageDir - KERNEL_BASE
 147         mov cr3, eax
 148         mov eax, cr0
 149         or eax, 0x80010000      ; PG and WP
 150         mov cr0, eax
 151         ; Jump to higher half
 152         lea eax, [.higherHalf]
 153         jmp eax
 154 .higherHalf:
 155         ; Load True GDT & IDT
 156         lgdt [gGDTPtr]
 157         lidt [gIDTPtr]
 158
 159         mov ebp, [gpMP_LocalAPIC]
 160         mov ebx, [ebp+0x20]     ; Read ID
 161         shr ebx, 24
 162         ;xchg bx, bx    ; MAGIC BREAK
 163         ; CL is now local APIC ID
 164         mov cl, BYTE [gaAPIC_to_CPU+ebx]
 165         xor ebx, ebx
 166         mov bl, cl
 167         ; BL is now the CPU ID
 168         mov BYTE [gaCPUs+ebx*8+1], 1
 169         ; Decrement the remaining CPU count
 170         dec DWORD [giNumInitingCPUs]
 171
 172         ; Create a stack
 173         lea edx, [ebx+1]
 174         shl edx, 5+2    ; *32 *4
 175         lea esp, [gInitAPStacks+edx]
 176         call MM_NewKStack
 177         mov esp, eax
 178
 179         ; Set TSS
 180         lea ecx, [ebx*8+0x30]
 181         ltr cx
 182         ; Save the CPU number to a debug register
 183         mov dr1, ebx
 184
 185         ;xchg bx, bx    ; MAGIC_BREAK
 186         ; Enable Local APIC
 187         mov DWORD [ebp+0x0F0], 0x000001EF       ; Spurious Interrupt Vector (0xEF)
 188         mov ecx, DWORD [giMP_TimerCount]
 189         mov DWORD [ebp+0x380], ecx      ; Set Initial Count
 190         mov DWORD [ebp+0x320], 0x000200EE       ; Enable timer on IVT#0xEE
 191         mov DWORD [ebp+0x330], 0x000100E0       ; ##Enable thermal sensor on IVT#0xE0
 192         mov DWORD [ebp+0x340], 0x000100D0       ; ##Enable performance counters on IVT#0xD0
 193         mov DWORD [ebp+0x350], 0x000100D1       ; ##Enable LINT0 on IVT#0xD1
 194         mov DWORD [ebp+0x360], 0x000100D2       ; ##Enable LINT1 on IVT#0xD2
 195         mov DWORD [ebp+0x370], 0x000100E1       ; ##Enable Error on IVT#0xE1
 196         mov DWORD [ebp+0x0B0], 0        ; Send an EOI (just in case)
 197
 198         ; CPU is now marked as initialised
 199         sti
 200         ;xchg bx, bx    ; MAGIC BREAK
 201 .hlt:
 202         hlt
 203         jmp .hlt
 204 %endif
 205
 206 [global GetEIP]
 207 GetEIP:
 208         mov eax, [esp]
 209         ret
 210
 211 ; int CallWithArgArray(void *Ptr, int NArgs, Uint *Args)
 212 ; Call a function passing the array as arguments
 213 [global CallWithArgArray]
 214 CallWithArgArray:
 215         push ebp
 216         mov ebp, esp
 217         mov ecx, [ebp+12]       ; Get NArgs
 218         mov edx, [ebp+16]
 219
 220 .top:
 221         mov eax, [edx+ecx*4-4]
 222         push eax
 223         loop .top
 224
 225         mov eax, [ebp+8]
 226         call eax
 227         lea esp, [ebp]
 228         pop ebp
 229         ret
 230
 231 [section .initpd]
 232 [global gaInitPageDir]
 233 [global gaInitPageTable]
 234 align 4096
 235 gaInitPageDir:
 236         dd      gaInitPageTable-KERNEL_BASE+3   ; 0x000 - Low kernel
 237         times 0x300-0x000-1     dd      0
 238         dd      gaInitPageTable-KERNEL_BASE+3   ; 0xC00 - High kernel
 239         times 0x3F0-0x300-1     dd      0
 240         dd      gaInitPageDir-KERNEL_BASE+3     ; 0xFC0 - Fractal
 241         times 0x400-0x3F0-1     dd      0
 242 align 4096
 243 gaInitPageTable:
 244         %assign i 0
 245         %rep 1024
 246         dd      i*0x1000+3
 247         %assign i i+1
 248         %endrep
 249 [global Kernel_Stack_Top]
 250 ALIGN 4096
 251         times 1024      dd      0
 252 Kernel_Stack_Top:
 253 gInitAPStacks:
 254         times 32*MAX_CPUS       dd      0
 255