Kernel/arch/x86_64/link.ld

   1 /*
   2  * Acess2 x86_64 Kernel
   3  * Linker Script
   4  */
   5
   6 _kernel_base = 0xFFFF800000000000;
   7
   8 OUTPUT_FORMAT(elf32-i386)
   9 OUTPUT_ARCH(i386:x86-64)
  10 ENTRY (start)
  11
  12 SECTIONS {
  13         . = 0x100000;
  14         gKernelBase = .;
  15         . += SIZEOF_HEADERS;
  16         __load_addr = .;
  17         .multiboot : AT(ADDR(.multiboot)) {
  18                 *(.multiboot)
  19         }
  20
  21         . += _kernel_base;
  22
  23         .text ALIGN(0x1000): AT(ADDR(.text) - _kernel_base) {
  24                 *(.text)
  25         }
  26
  27         .usertext ALIGN(0x1000): AT(ADDR(.usertext) - _kernel_base) {
  28                 _UsertextBase = .;
  29                 *(.usertext)
  30         }
  31         _UsertextEnd = .;
  32
  33         .rodata ALIGN(0x1000): AT(ADDR(.rodata) - _kernel_base) {
  34                 *(.initpd)
  35                 *(.rodata)
  36                 *(.rdata)
  37                 gKernelModules = .;
  38                 *(KMODULES)
  39                 gKernelModulesEnd = .;
  40                 . = ALIGN(4);
  41                 gKernelSymbols = .;
  42                 *(KEXPORT)
  43                 gKernelSymbolsEnd = .;
  44         }
  45         /*
  46         .debug_abbrev : { *(.debug_abbrev) }
  47         .debug_info : { *(.debug_info) }
  48         .debug_line : { *(.debug_line) }
  49         .debug_loc : { *(.debug_loc) }
  50         .debug_pubnames : { *(.debug_pubnames) }
  51         .debug_aranges : { *(.debug_aranges) }
  52         .debug_ranges : { *(.debug_ranges) }
  53         .debug_str : { *(.debug_str) }
  54         .debug_frame : { *(.debug_frame) }
  55         */
  56
  57         .padata ALIGN (0x1000) : AT(ADDR(.padata) - _kernel_base) {
  58                 *(.padata)
  59         }
  60
  61         .data ALIGN (0x1000) : AT(ADDR(.data) - _kernel_base) {
  62                 *(.data)
  63         }
  64
  65         __bss_start = .;
  66         .bss : AT(ADDR(.bss) - _kernel_base) {
  67                 _sbss = .;
  68                 *(COMMON)
  69                 *(.bss)
  70                 _ebss = .;
  71         }
  72         gKernelEnd = (. + 0xFFF)&0xFFFFFFFFFFFFF000;
  73 }