Kernel/arch/x86_64/link.ld

   1 /*
   2  * Acess2 x86_64 Kernel
   3  * Linker Script
   4  */
   5
   6 /* _kernel_base = 0xFFFF800000000000; */
   7 /* -2 GiB */
   8 _kernel_base = 0xFFFFFFFF80000000;
   9
  10 OUTPUT_FORMAT(elf32-i386)
  11 OUTPUT_ARCH(i386:x86-64)
  12 ENTRY(start)
  13
  14 SECTIONS {
  15         . = 0x100000;
  16         gKernelBase = .;
  17         . += SIZEOF_HEADERS;
  18         __load_addr = .;
  19         .multiboot : AT(ADDR(.multiboot)) {
  20                 *(.multiboot)
  21         }
  22
  23         . += _kernel_base;
  24
  25         .text ALIGN(0x1000): AT(ADDR(.text) - _kernel_base) {
  26                 *(.text)
  27         }
  28
  29         .usertext ALIGN(0x1000): AT(ADDR(.usertext) - _kernel_base) {
  30                 _UsertextBase = .;
  31                 *(.usertext)
  32         }
  33         _UsertextEnd = .;
  34
  35         .rodata ALIGN(0x1000): AT(ADDR(.rodata) - _kernel_base) {
  36                 *(.initpd)
  37                 *(.rodata .rodata.*)
  38                 *(.rdata)
  39
  40                 . = ALIGN(0x10);
  41                 gKernelModules = .;
  42                 *(KMODULES)
  43                 gKernelModulesEnd = .;
  44                 . = ALIGN(0x10);
  45                 gKernelSymbols = .;
  46                 *(KEXPORT)
  47                 gKernelSymbolsEnd = .;
  48         }
  49
  50         .padata ALIGN (0x1000) : AT(ADDR(.padata) - _kernel_base) {
  51                 *(.padata)
  52         }
  53
  54         .data ALIGN (0x1000) : AT(ADDR(.data) - _kernel_base) {
  55                 *(.data)
  56         }
  57
  58         __bss_start = .;
  59         .bss : AT(ADDR(.bss) - _kernel_base) {
  60                 _sbss = .;
  61                 *(COMMON)
  62                 *(.bss)
  63                 _ebss = .;
  64         }
  65         gKernelEnd = (. + 0xFFF)&0xFFFFFFFFFFFFF000;
  66 }