KernelLand/Kernel/arch/armv6/proc.S

   1 /*
   2  * Acess2 ARM
   3  * - By John Hodge (thePowersGang)
   4  *
   5  * arch/arm7/proc.S
   6  * - Process management assembly
   7  */
   8
   9 #include "include/assembly.h"
  10
  11 .globl KernelThreadHeader
  12 @ SP+12: Argument 1
  13 @ SP+8: Argument Count
  14 @ SP+4: Function
  15 @ SP+0: Thread Pointer
  16 KernelThreadHeader:
  17         ldr r0, [sp],#4
  18         @ TODO: Do something with the thread pointer
  19
  20         ldr r4, [sp],#4 @ Function
  21         @ Get argument
  22         ldr r0, [sp],#4
  23
  24         blx r4
  25
  26         ldr r0, =0
  27         bl Threads_Exit
  28         b .
  29
  30 .globl SwitchTask
  31 @ R0: New stack
  32 @ R1: Pointer to where to save old stack
  33 @ R2: New IP
  34 @ R3: Pointer to save old IP
  35 @ SP+0: New address space
  36 SwitchTask:
  37         push {r4-r12,lr}
  38
  39         @ Save IP
  40         ldr r4, =.return
  41         str r4, [r3]
  42         @ Save SP
  43         str sp, [r1]
  44
  45         @ Only update TTBR0 if the task has an explicit address space
  46         ldr r1, [sp,#4*10]
  47         tst r1, r1
  48         mcrne p15, 0, r1, c2, c0, 0     @ Set TTBR0 to r0
  49 #       mov r1, #1
  50         mcrne p15, 0, r1, c8, c7, 0     @ TLBIALL - Invalid user space
  51
  52         @ Restore state
  53         mov sp, r0
  54         bx r2
  55
  56 .return:
  57         pop {r4-r12,pc}
  58
  59 .extern MM_Clone
  60 .extern MM_DumpTables
  61 .globl Proc_CloneInt
  62 Proc_CloneInt:
  63         @ R0: SP Destination
  64         @ R1: Mem Destination
  65         push {r4-r12,lr}
  66         mov r4, r1      @ Save mem destination
  67         str sp, [r0]    @ Save SP to SP dest
  68
  69         bl MM_Clone
  70         str r0, [r4]    @ Save clone return to Mem Dest
  71
  72         ldr r0, =Proc_CloneInt_new
  73         pop {r4-r12,pc}
  74 Proc_CloneInt_new:
  75         mov r0, #0
  76         pop {r4-r12,pc}
  77
  78 @ R0: New user SP
  79 @ Return: Old user SP
  80 .globl Proc_int_SwapUserSP
  81 Proc_int_SwapUserSP:
  82         cps #31 @ Go to system mode
  83         mov r1, sp
  84         tst r0, r0      @ Only update if non-zero
  85         movne sp, r0
  86         mov r0, r1
  87         cps #19
  88         mov pc, lr
  89
  90 .section .usertext, "ax"
  91 .globl Proc_int_DropToUser
  92 @ R0: User IP
  93 @ R1: User SP
  94 Proc_int_DropToUser:
  95         cps #16
  96         mov sp, r1
  97         mov pc, r0
  98
  99 .section .rodata
 100 csProc_CloneInt_NewTaskMessage:
 101         .asciz "New task PC=%p, R4=%p, sp=%p"
 102 csProc_CloneInt_OldTaskMessage:
 103         .asciz "Parent task PC=%p, R4=%p, SP=%p"
 104
 105 @ vim: ft=armv7