KernelLand/Kernel/arch/x86/start.asm

   1 ; AcessOS Microkernel Version
   2 ; Start.asm
   3
   4 [bits 32]
   5
   6 KERNEL_BASE     equ 0xC0000000
   7 %define MAX_CPUS        16
   8
   9 [extern __load_addr]
  10 [extern __bss_start]
  11 [extern gKernelEnd]
  12 [section .multiboot]
  13 mboot:
  14         ; Multiboot macros to make a few lines later more readable
  15         MULTIBOOT_PAGE_ALIGN    equ 1<<0
  16         MULTIBOOT_MEMORY_INFO   equ 1<<1
  17         MULTIBOOT_HEADER_MAGIC  equ 0x1BADB002
  18         MULTIBOOT_HEADER_FLAGS  equ MULTIBOOT_PAGE_ALIGN | MULTIBOOT_MEMORY_INFO
  19         MULTIBOOT_CHECKSUM      equ -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)
  20
  21         ; This is the GRUB Multiboot header. A boot signature
  22         dd MULTIBOOT_HEADER_MAGIC
  23         dd MULTIBOOT_HEADER_FLAGS
  24         dd MULTIBOOT_CHECKSUM
  25         dd mboot; - KERNEL_BASE ;Location of Multiboot Header
  26
  27 ; Multiboot 2 Header
  28 ;mboot2:
  29 ;       MULTIBOOT2_HEADER_MAGIC equ 0xE85250D6
  30 ;       MULTIBOOT2_HEADER_ARCH  equ 0
  31 ;       MULTIBOOT2_HEADER_LENGTH        equ (mboot2_end-mboot2)
  32 ;       MULTIBOOT2_CHECKSUM     equ -(MULTIBOOT2_HEADER_MAGIC + MULTIBOOT2_HEADER_ARCH + MULTIBOOT2_HEADER_LENGTH)
  33 ;
  34 ;       dd MULTIBOOT2_HEADER_MAGIC
  35 ;       dd MULTIBOOT2_HEADER_ARCH
  36 ;       dd MULTIBOOT2_HEADER_LENGTH
  37 ;       dd MULTIBOOT2_CHECKSUM
  38 ;       ; MBoot2 Address Header
  39 ;       dw      2, 0
  40 ;       dd      8 + 16
  41 ;       dd      mboot2  ; Location of Multiboot Header
  42 ;       dd      __load_addr - KERNEL_BASE       ; Kernel Load base
  43 ;       dd      __bss_start - KERNEL_BASE       ; Kernel Data End
  44 ;       dd      gKernelEnd - KERNEL_BASE        ; Kernel BSS End
  45 ;       ; MBoot2 Entry Point Tag
  46 ;       dw      3, 0
  47 ;       dd      8 + 4
  48 ;       dd      start - KERNEL_BASE
  49 ;       ; MBoot2 Module Alignment Tag
  50 ;       dw      6, 0
  51 ;       dd      12      ; ???
  52 ;       dd      0       ; Search me, seems it wants padding
  53 ;       ; Terminator
  54 ;       dw      0, 0
  55 ;       dd      8
  56 ;mboot2_end:
  57
  58 [section .text]
  59 [extern kmain]
  60 [global start]
  61 start:
  62         ; Just show we're here
  63         mov WORD [0xB8000], 0x0741      ; 'A'
  64
  65         ; Set up stack
  66         mov esp, Kernel_Stack_Top
  67
  68         ; Start Paging
  69         mov ecx, gaInitPageDir - KERNEL_BASE
  70         mov cr3, ecx
  71         mov ecx, cr0
  72         or ecx, 0x80010000      ; PG and WP
  73         mov cr0, ecx
  74
  75         mov WORD [0xB8002], 0x0763      ; 'c'
  76
  77         ; Set GDT
  78         lgdt [gGDTPtr]
  79         mov cx, 0x10    ; PL0 Data
  80         mov ss, cx
  81         mov ds, cx
  82         mov es, cx
  83         mov gs, cx
  84         mov fs, cx
  85         mov WORD [0xB8004], 0x0765      ; 'e'
  86         jmp 0x08:.higher_half
  87 .higher_half:
  88
  89         mov WORD [0xB8006], 0x0773      ; 's'
  90         mov WORD [0xB8008], 0x0773      ; 's'
  91
  92         ; Call the kernel
  93         push ebx        ; Multiboot Info
  94         push eax        ; Multiboot Magic Value
  95         mov WORD [0xB800A], 0x0732      ; '2'
  96         call kmain
  97
  98         ; Halt the Machine
  99         cli
 100 .hlt:
 101         hlt
 102         jmp .hlt
 103
 104 ;
 105 ; Multiprocessing AP Startup Code (Must be within 0 - 0x10FFF0)
 106 ;
 107 %if USE_MP
 108 [extern gIDTPtr]
 109 [extern gpMP_LocalAPIC]
 110 [extern giMP_TimerCount]
 111 [extern gaAPIC_to_CPU]
 112 [extern gaCPUs]
 113 [extern giNumInitingCPUs]
 114 [extern MM_NewKStack]
 115 [extern Proc_InitialiseSSE]
 116
 117 lGDTPtr:        ; Local GDT Pointer
 118         dw      3*8-1
 119         dd      gGDT-KERNEL_BASE
 120
 121 [bits 16]
 122 [global APWait]
 123 APWait:
 124         ;xchg bx, bx
 125 .hlt:
 126         ;hlt
 127         jmp .hlt
 128 [extern Proc_Reschedule]
 129 [global APStartup]
 130 APStartup:
 131         ;xchg bx, bx    ; MAGIC BREAK!
 132         ; Load initial GDT
 133         mov ax, 0xFFFF
 134         mov ds, ax
 135         lgdt [DWORD ds:lGDTPtr-KERNEL_BASE-0xFFFF0]
 136         ; Enable PMode in CR0
 137         mov eax, cr0
 138         or al, 1
 139         mov cr0, eax
 140         ; Jump into PMode
 141         jmp 08h:DWORD .ProtectedMode-KERNEL_BASE
 142 [bits 32]
 143 .ProtectedMode:
 144         ; Load segment registers
 145         mov ax, 0x10
 146         mov ss, ax
 147         mov ds, ax
 148         mov es, ax
 149         mov fs, ax
 150         mov gs, ax
 151         ; Start Paging
 152         mov eax, gaInitPageDir - KERNEL_BASE
 153         mov cr3, eax
 154         mov eax, cr0
 155         or eax, 0x80010000      ; PG and WP
 156         mov cr0, eax
 157         ; Jump to higher half
 158         lea eax, [.higherHalf]
 159         jmp eax
 160 .higherHalf:
 161         ; Load True GDT & IDT
 162         lgdt [gGDTPtr]
 163         lidt [gIDTPtr]
 164
 165         mov ebp, [gpMP_LocalAPIC]
 166         mov ebx, [ebp+0x20]     ; Read ID
 167         shr ebx, 24
 168         ;xchg bx, bx    ; MAGIC BREAK
 169         ; BL is now local APIC ID
 170         mov cl, BYTE [gaAPIC_to_CPU+ebx]
 171         xor ebx, ebx
 172         mov bl, cl
 173         ; BL is now the CPU ID
 174         mov dr1, ebx    ; Save the CPU number to a debug register
 175         ; Mark the CPU as up
 176         mov BYTE [gaCPUs+ebx*8+1], 1
 177         ; Decrement the remaining CPU count
 178         dec DWORD [giNumInitingCPUs]
 179
 180         ; Create a stack
 181         lea edx, [ebx+1]
 182         shl edx, 5+2    ; *32 *4
 183         lea esp, [gInitAPStacks+edx]
 184         call MM_NewKStack
 185         mov esp, eax
 186
 187         ; Set TSS
 188         lea ecx, [ebx*8+0x30]
 189         ltr cx
 190
 191         ;xchg bx, bx    ; MAGIC_BREAK
 192         ; Enable Local APIC
 193         mov DWORD [ebp+0x0F0], 0x000001EF       ; Spurious Interrupt Vector (0xEF)
 194         mov ecx, DWORD [giMP_TimerCount]
 195         mov DWORD [ebp+0x380], ecx      ; Set Initial Count
 196         mov DWORD [ebp+0x320], 0x000200EE       ; Enable timer on IVT#0xEE
 197         mov DWORD [ebp+0x330], 0x000100E0       ; ##Enable thermal sensor on IVT#0xE0
 198         mov DWORD [ebp+0x340], 0x000100D0       ; ##Enable performance counters on IVT#0xD0
 199         mov DWORD [ebp+0x350], 0x000100D1       ; ##Enable LINT0 on IVT#0xD1
 200         mov DWORD [ebp+0x360], 0x000100D2       ; ##Enable LINT1 on IVT#0xD2
 201         mov DWORD [ebp+0x370], 0x000100E1       ; ##Enable Error on IVT#0xE1
 202         mov DWORD [ebp+0x0B0], 0        ; Send an EOI (just in case)
 203
 204         ; Initialise SSE support
 205         call Proc_InitialiseSSE
 206
 207         ; CPU is now marked as initialised
 208
 209 .hlt:
 210         sti
 211         call Proc_Reschedule
 212         hlt
 213         jmp .hlt
 214 %endif
 215
 216 [global GetEIP]
 217 GetEIP:
 218         mov eax, [esp]
 219         ret
 220
 221 ; int CallWithArgArray(void *Ptr, int NArgs, Uint *Args)
 222 ; Call a function passing the array as arguments
 223 [global CallWithArgArray]
 224 CallWithArgArray:
 225         push ebp
 226         mov ebp, esp
 227         mov ecx, [ebp+12]       ; Get NArgs
 228         mov edx, [ebp+16]
 229
 230 .top:
 231         mov eax, [edx+ecx*4-4]
 232         push eax
 233         loop .top
 234
 235         mov eax, [ebp+8]
 236         call eax
 237         lea esp, [ebp]
 238         pop ebp
 239         ret
 240
 241 [section .data]
 242 ; GDT
 243 GDT_SIZE        equ     (1+2*2+1+MAX_CPUS)*8
 244 [global gGDT]
 245 gGDT:
 246         ; PL0 - Kernel
 247         ; PL3 - User
 248         dd 0x00000000, 0x00000000       ; 00 NULL Entry
 249         dd 0x0000FFFF, 0x00CF9A00       ; 08 PL0 Code
 250         dd 0x0000FFFF, 0x00CF9200       ; 10 PL0 Data
 251         dd 0x0000FFFF, 0x00CFFA00       ; 18 PL3 Code
 252         dd 0x0000FFFF, 0x00CFF200       ; 20 PL3 Data
 253         dd 26*4-1, 0x00408900   ; 28 Double Fault TSS
 254         times MAX_CPUS  dd 26*4-1, 0x00408900   ; 30+ TSSes
 255 [global gGDTPtr]
 256 gGDTPtr:
 257         dw      GDT_SIZE-1
 258         dd      gGDT
 259
 260 [section .initpd]
 261 [global gaInitPageDir]
 262 [global gaInitPageTable]
 263 align 4096
 264 gaInitPageDir:
 265         dd      gaInitPageTable-KERNEL_BASE+3   ; 0x000 - Low kernel
 266         times 0x300-0x000-1     dd      0
 267         dd      gaInitPageTable-KERNEL_BASE+3   ; 0xC00 - High kernel
 268         times 0x3F0-0x300-1     dd      0
 269         dd      gaInitPageDir-KERNEL_BASE+3     ; 0xFC0 - Fractal
 270         times 0x400-0x3F0-1     dd      0
 271 align 4096
 272 gaInitPageTable:
 273         %assign i 0
 274         %rep 1024
 275         dd      i*0x1000+3
 276         %assign i i+1
 277         %endrep
 278 [global Kernel_Stack_Top]
 279 ALIGN 4096
 280         times 1024      dd      0
 281 Kernel_Stack_Top:
 282 gInitAPStacks:
 283         times 32*MAX_CPUS       dd      0
 284
 285 ; vim: ft=nasm ts=8