Kernel/arch/armv7/link.ld

   1 ENTRY (_start)
   2
   3 _kernel_base = 0x80000000;
   4 _usertext_vbase = 0xFFFFE000;
   5
   6 SECTIONS
   7 {
   8         . = 0;
   9         .init :
  10         {
  11                 *(.init)
  12         }
  13         . += _kernel_base;
  14         .text : AT( ADDR(.text) - _kernel_base )
  15         {
  16                 *(.text*)
  17                 *(.rodata*)
  18         }
  19
  20
  21         /* HACKS: User accesible .text section */
  22         . = ALIGN(0x1000);
  23         gUsertextPhysStart = . - _kernel_base;
  24         . = _usertext_vbase;
  25         .usertext : AT( gUsertextPhysStart )
  26         {
  27                 *(.usertext)
  28         }
  29         . += gUsertextPhysStart + _kernel_base - _usertext_vbase;
  30
  31         /* 0x4000 (4 pages) alignment needed for root table */
  32         .data ALIGN(0x4000) : AT( ADDR(.data) - _kernel_base )
  33         {
  34                 *(.padata)
  35                 *(.data*)
  36
  37                 gKernelSymbols = .;
  38                 *(KEXPORT)
  39                 gKernelSymbolsEnd = .;
  40
  41                 gKernelModules = .;
  42                 *(KMODULES)
  43                 gKernelModulesEnd = .;
  44         }
  45         .bss : AT( ADDR(.bss) - _kernel_base )
  46         {
  47                 bss_start = .;
  48                 *(.bss*)
  49                 *(COMMON*)
  50                 . = ALIGN(0x1000);
  51                 *(.pabss)
  52                 bss_end = .;
  53         }
  54         gKernelEnd = .;
  55 }