Kernel/arch/armv7/proc.S

   1 /*
   2  * Acess2 ARM
   3  * - By John Hodge (thePowersGang)
   4  *
   5  * arch/arm7/proc.S
   6  * - Process management assembly
   7  */
   8
   9 #include "include/assembly.h"
  10
  11 .globl KernelThreadHeader
  12 @ SP+12: Argument 1
  13 @ SP+8: Argument Count
  14 @ SP+4: Function
  15 @ SP+0: Thread Pointer
  16 KernelThreadHeader:
  17         ldr r0, [sp],#4
  18         @ TODO: Do something with the thread pointer
  19
  20         ldr r4, [sp],#4 @ Function
  21         @ Get argument
  22         ldr r0, [sp],#4
  23
  24         blx r4
  25
  26         ldr r0, =0
  27         bl Threads_Exit
  28         b .
  29
  30 .globl SwitchTask
  31 @ R0: New stack
  32 @ R1: Pointer to where to save old stack
  33 @ R2: New IP
  34 @ R3: Pointer to save old IP
  35 @ SP+0: New address space
  36 SwitchTask:
  37         push {r4-r12,lr}
  38
  39         @ Save IP
  40         ldr r4, =.return
  41         str r4, [r3]
  42         @ Save SP
  43         str sp, [r1]
  44
  45         @ Only update TTBR0 if the task has an explicit address space
  46         ldr r1, [sp,#4*10]
  47         tst r1, r1
  48         mcrne p15, 0, r1, c2, c0, 0     @ Set TTBR0 to r0
  49         mov r1, #0
  50         mcrne p15, 0, r1, c8, c7, 0     @ TLBIALL - Invalidate all
  51
  52         @ Restore SP
  53         mov sp, r0
  54
  55         bx r2
  56
  57 .return:
  58         pop {r4-r12,pc}
  59
  60 .extern MM_Clone
  61 .extern MM_DumpTables
  62 .globl Proc_CloneInt
  63 Proc_CloneInt:
  64         @ R0: SP Destination
  65         @ R1: Mem Destination
  66         push {r4-r12,lr}
  67         mov r4, r1      @ Save mem destination
  68         str sp, [r0]    @ Save SP to SP dest
  69
  70         bl MM_Clone
  71         str r0, [r4]    @ Save clone return to Mem Dest
  72
  73         ldr r0, =Proc_CloneInt_new
  74         pop {r4-r12,pc}
  75 Proc_CloneInt_new:
  76         mov r0, #0
  77         pop {r4-r12,pc}
  78
  79 @ R0: New user SP
  80 @ Return: Old user SP
  81 .globl Proc_int_SwapUserSP
  82 Proc_int_SwapUserSP:
  83         cps #31 @ Go to system mode
  84         mov r1, sp
  85         tst r0, r0      @ Only update if non-zero
  86         movne sp, r0
  87         mov r0, r1
  88         cps #19
  89         mov pc, lr
  90
  91 .section .usertext, "ax"
  92 .globl Proc_int_DropToUser
  93 @ R0: User IP
  94 @ R1: User SP
  95 Proc_int_DropToUser:
  96         cps #16
  97         mov sp, r1
  98         mov pc, r0
  99
 100 .section .rodata
 101 csProc_CloneInt_NewTaskMessage:
 102         .asciz "New task PC=%p, R4=%p, sp=%p"
 103 csProc_CloneInt_OldTaskMessage:
 104         .asciz "Parent task PC=%p, R4=%p, SP=%p"