Kernel/arch/armv7/start.S

   1
   2 #include "include/assembly.h"
   3 #include "include/options.h"
   4
   5 @
   6 @ Exception defs taken from ARM DDI 0406B
   7 @
   8 .section .init
   9 interrupt_vector_table:
  10 ivt_reset:      b _start        @ 0x00 Reset
  11 ivt_undef:      b .             @ 0x04 #UD
  12 ivt_svc:        b SVC_Handler   @ 0x08 SVC (used to be called SWI)
  13 ivt_prefetch:   b PrefetchAbort @ 0x0C Prefetch abort
  14 ivt_data:       b DataAbort     @ 0x10 Data abort
  15 ivt_unused:     b .             @ 0x14 Not Used
  16 ivt_irq:        b IRQHandler    @ 0x18 IRQ
  17 ivt_fiq:        b .             @ 0x1C FIQ (Fast interrupt)
  18
  19 .globl _start
  20 _start:
  21         ldr r2, =UART0_PADDR
  22         mov r1, #'A'
  23         str r1, [r2]
  24
  25         ldr r0, =kernel_table0-KERNEL_BASE
  26         mcr p15, 0, r0, c2, c0, 1       @ Set TTBR1 to r0
  27         mcr p15, 0, r0, c2, c0, 0       @ Set TTBR0 to r0 too (for identity)
  28
  29         mov r1, #'c'
  30         str r1, [r2]
  31
  32         mov r0, #1
  33         mcr p15, 0, r0, c2, c0, 2       @ Set TTCR to 1 (50/50 split)
  34
  35         mov r1, #'e'
  36         str r1, [r2]
  37
  38         mov r0, #3
  39         mcr p15, 0, r0, c3, c0, 0       @ Set Domain 0 to Manager
  40
  41         mov r1, #'s'
  42         str r1, [r2]
  43
  44         @ Enable VMSA
  45         mrc p15, 0, r0, c1, c0, 0
  46         orr r0, r0, #1
  47         orr r0, r0, #1 << 23
  48         mcr p15, 0, r0, c1, c0, 0
  49
  50         ldr r2, =0xF1000000
  51         mov r1, #'s'
  52         str r1, [r2]
  53
  54         @ Enable access faults on domains 0 & 1
  55         mov r0, #0x55   @ 01010101b
  56         mcr p15, 0, r0, c3, c0, 0
  57
  58         mov r1, #'2'
  59         str r1, [r2]
  60
  61         @
  62         @ Check for security extensions
  63         @
  64         mrc p15, 0, r0, c0, c1, 1
  65         and r0, #0xF0
  66         @ - Present
  67         ldrne r0,=KERNEL_BASE
  68         mcrne p15, 0, r0, c12, c0, 0    @ Set the VBAR (brings exceptions into high memory)
  69         @ - Absent
  70         mrceq p15, 0, r0, c1, c0, 0     @ Set SCTLR.V
  71         orreq r0, #0x2000
  72         mcreq p15, 0, r0, c1, c0, 0
  73
  74         mov r1, #'-'
  75         str r1, [r2]
  76
  77         @ Prepare for interrupts
  78         cps #18 @ IRQ Mode
  79         ldr sp, =irqstack+0x1000        @ Set up stack
  80         cps #23 @ Abort Mode
  81         ldr sp, =abortstack+0x1000
  82         cps #19
  83
  84         mov r1, #'a'
  85         str r1, [r2]
  86         mov r1, #'r'
  87         str r1, [r2]
  88         mov r1, #'m'
  89         str r1, [r2]
  90         mov r1, #13
  91         str r1, [r2]
  92         mov r1, #10
  93         str r1, [r2]
  94
  95 .extern bss_start
  96 .extern bss_size_div_4
  97 .zero_bss:
  98         ldr r0, =bss_start
  99         ldr r1, =bss_end
 100         mov r3, #0
 101 .zero_bss_loop:
 102         str r3, [r0],#4
 103         cmp r0, r1
 104         bls .zero_bss_loop
 105
 106 .goto_c:
 107         ldr sp, =0x80000000-8   @ Set up stack (top of user range)
 108         ldr r0, =kmain
 109         mov pc, r0
 110 1:      b 1b    @ Infinite loop
 111
 112 .comm irqstack, 0x1000  @ ; 4KiB Stack
 113 .comm abortstack, 0x1000        @ ; 4KiB Stack
 114
 115 .extern SyscallHandler
 116 SVC_Handler:
 117 @       sub lr, #4
 118         srsdb sp!, #19  @ Save state to stack
 119         cpsie ifa, #19  @ Ensure we're in supervisor with interrupts enabled (should already be there)
 120         push {r0-r12}
 121
 122         ldr r4, [lr,#-4]
 123         mvn r5, #0xFF000000
 124         and r4, r5
 125
 126         tst r4, #0x1000
 127         bne .arm_specifics
 128
 129         push {r4}
 130
 131         mov r0, sp
 132         ldr r4, =SyscallHandler
 133         blx r4
 134
 135 @       ldr r0, =csSyscallPrintRetAddr
 136 @       ldr r1, [sp,#9*4+5*4]
 137 @       ldr r4, =Log
 138 @       blx r4
 139
 140         pop {r2}        @ errno
 141         pop {r0,r1}     @ Ret/RetHi
 142         add sp, #2*4    @ Saved r2/r3
 143
 144         pop {r4-r12}
 145         rfeia sp!       @ Pop state (actually RFEFD)
 146 .arm_specifics:
 147         and r4, #0xFF
 148         mov r0, r4      @ Number
 149         mov r1, sp      @ Arguments
 150
 151         ldr r4, =ARMv7_int_HandleSyscalls
 152         blx r4
 153
 154         add sp, #4*4
 155         pop {r4-r12}
 156         rfeia sp!
 157
 158
 159 .globl gpIRQHandler
 160 gpIRQHandler:   .long   0
 161 IRQ_saved_sp:   .long   0
 162 IRQ_saved_lr:   .long   0
 163 .globl IRQHandler
 164 IRQHandler:
 165         sub lr, #4      @ Adjust LR to the correct value
 166         srsdb sp!, #19  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 167         cps #19
 168
 169         PUSH_GPRS
 170
 171 @       ldr r0, =csIRQ_Tag
 172 @       ldr r1, =csIRQ_Fmt
 173 @       ldr r4, =Log_Debug
 174 @       blx r4
 175
 176         @ Call the registered handler
 177         ldr r0, gpIRQHandler
 178         blx r0
 179
 180         @ Restore CPU state
 181         POP_GPRS
 182         cpsie i
 183         rfeia sp!       @ Pop state (actually RFEFD)
 184         bx lr
 185
 186 .globl DataAbort
 187 DataAbort:
 188         sub lr, #8      @ Adjust LR to the correct value
 189         srsdb sp!, #23  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 190 @       cpsid ifa, #19
 191         PUSH_GPRS
 192
 193         mov r3, #0      @ not a prefetch abort
 194         mrc p15, 0, r2, c5, c0, 0       @ Read DFSR (Data Fault Status Register) to R2
 195         mrc p15, 0, r1, c6, c0, 0       @ Read DFAR (Data Fault Address Register) into R1
 196         mov r0, lr      @ PC
 197         ldr r4, =MM_PageFault
 198         blx r4
 199
 200         POP_GPRS
 201         rfeia sp!       @ Pop state (actually RFEFD)
 202
 203 .globl PrefetchAbort
 204 PrefetchAbort:
 205         sub lr, #4      @ Adjust LR to the correct value
 206         srsdb sp!, #23  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 207 @       cpsid ifa, #19
 208         PUSH_GPRS
 209
 210         ldr r0, =csAbort_Tag
 211         ldr r1, =csPrefetchAbort_Fmt
 212 #       mov r2, lr
 213         mrc p15, 0, r2, c6, c0, 2       @ Read IFAR (Instruction Fault Address Register) into R3
 214         mrc p15, 0, r3, c5, c0, 1       @ Read IFSR (Instruction Fault Status Register) into R3
 215         ldr r5, =Log_Error
 216         blx r5
 217
 218         b .
 219
 220 .section .rodata
 221 csIRQ_Tag:
 222 csAbort_Tag:
 223         .asciz "ARMv7"
 224 csIRQ_Fmt:
 225         .asciz "IRQ"
 226 csDataAbort_Fmt:
 227         .asciz "Data Abort - %p accessed %p, DFSR=%x Unk:%x Unk:%x"
 228 csPrefetchAbort_Fmt:
 229         .asciz "Prefetch Abort at %p, IFSR=%x"
 230 csSyscallPrintRetAddr:
 231         .asciz "Syscall ret to %p"
 232
 233 .section .padata
 234 .globl kernel_table0
 235
 236 kernel_table0:
 237         .long 0x00000402        @ Identity map the first 1 MiB
 238         .rept 0x7FC - 1
 239                 .long 0
 240         .endr
 241         .long user_table1_map + 0x000 - KERNEL_BASE + 1 @ 0x7FC00000
 242         .long user_table1_map + 0x400 - KERNEL_BASE + 1 @ 0x7FD00000
 243         .long user_table1_map + 0x800 - KERNEL_BASE + 1 @ KStacks
 244         .long user_table1_map + 0xC00 - KERNEL_BASE + 1
 245         @ 0x80000000 - User/Kernel split
 246         .long 0x00000402        @ Map first 4 MiB to 2GiB (KRW only)
 247         .long 0x00100402        @
 248         .long 0x00200402        @
 249         .long 0x00300402        @
 250         .rept 0xF00 - 0x800 - 4
 251                 .long 0
 252         .endr
 253 #if PCI_PADDR
 254         .long PCI_PADDR +  0*(1 << 20) + 0x402  @ Map PCI config space
 255         .long PCI_PADDR +  1*(1 << 20) + 0x402
 256         .long PCI_PADDR +  2*(1 << 20) + 0x402
 257         .long PCI_PADDR +  3*(1 << 20) + 0x402
 258         .long PCI_PADDR +  4*(1 << 20) + 0x402
 259         .long PCI_PADDR +  5*(1 << 20) + 0x402
 260         .long PCI_PADDR +  6*(1 << 20) + 0x402
 261         .long PCI_PADDR +  7*(1 << 20) + 0x402
 262         .long PCI_PADDR +  8*(1 << 20) + 0x402
 263         .long PCI_PADDR +  9*(1 << 20) + 0x402
 264         .long PCI_PADDR + 10*(1 << 20) + 0x402
 265         .long PCI_PADDR + 11*(1 << 20) + 0x402
 266         .long PCI_PADDR + 12*(1 << 20) + 0x402
 267         .long PCI_PADDR + 13*(1 << 20) + 0x402
 268         .long PCI_PADDR + 14*(1 << 20) + 0x402
 269         .long PCI_PADDR + 15*(1 << 20) + 0x402
 270 #else
 271         .rept 16
 272                 .long 0
 273         .endr
 274 #endif
 275         .long hwmap_table_0 + 0x000 - KERNEL_BASE + 1
 276         .long hwmap_table_0 + 0x400 - KERNEL_BASE + 1
 277         .long hwmap_table_0 + 0x800 - KERNEL_BASE + 1
 278         .long hwmap_table_0 + 0xC00 - KERNEL_BASE + 1
 279         .rept 0xFF8 - 0xF00 - 16 - 4
 280                 .long 0
 281         .endr
 282         @ Page fractals
 283         .long kernel_table1_map + 0x000 - KERNEL_BASE + 1
 284         .long kernel_table1_map + 0x400 - KERNEL_BASE + 1
 285         .long kernel_table1_map + 0x800 - KERNEL_BASE + 1
 286         .long kernel_table1_map + 0xC00 - KERNEL_BASE + 1
 287         .long kernel_exception_map + 0x000 - KERNEL_BASE + 1
 288         .long kernel_exception_map + 0x400 - KERNEL_BASE + 1
 289         .long kernel_exception_map + 0x800 - KERNEL_BASE + 1
 290         .long kernel_exception_map + 0xC00 - KERNEL_BASE + 1
 291
 292 @ PID0 user table
 293 .globl user_table1_map
 294 @ User table1 data table (only the first half is needed)
 295 @ - Abused to provide kernel stacks in the unused half of the table
 296 user_table1_map:        @ Size = 4KiB (only 2KiB used)
 297         .rept 0x800/4-1
 298                 .long 0
 299         .endr
 300         .long user_table1_map - KERNEL_BASE + 0x13      @ ...1FF000 = 0x7FDFF000
 301         @ Kernel stack zone
 302         .long kernel_table0 + 0x0000 - KERNEL_BASE + 0x13       @ ...200000 = 0x7FE00000
 303         .long kernel_table0 + 0x1000 - KERNEL_BASE + 0x13       @ ...201000 = 0x7FE01000
 304         .rept (0x800/4)-(MM_KSTACK_SIZE/0x1000)-2
 305                 .long 0
 306         .endr
 307         #if MM_KSTACK_SIZE != 0x2000
 308         #error Kernel stack size not changed in start.S
 309         #endif
 310         .long stack + 0x0000 - KERNEL_BASE + 0x13       @ Kernel Stack
 311         .long stack + 0x1000 - KERNEL_BASE + 0x13       @
 312
 313 .globl kernel_table1_map
 314 kernel_table1_map:      @ Size = 4KiB
 315         .rept (0xF00+16)/4
 316                 .long 0
 317         .endr
 318         .long hwmap_table_0 - KERNEL_BASE + 0x13
 319         .rept 0xFF8/4 - (0xF00+16)/4 - 1
 320                 .long 0
 321         .endr
 322         .long kernel_table1_map - KERNEL_BASE + 0x13
 323         .long kernel_exception_map - KERNEL_BASE + 0x13
 324
 325 @ Hardware mappings
 326 .globl hwmap_table_0
 327 hwmap_table_0:
 328         .long UART0_PADDR + 0x13        @ UART0
 329         .rept 1024 - 1
 330                 .long 0
 331         .endr
 332 .globl kernel_exception_map
 333 kernel_exception_map:
 334         @ Padding
 335         .rept 1024-256
 336                 .long 0
 337         .endr
 338         @ Align to nearly the end
 339         .rept 256-16
 340                 .long   0
 341         .endr
 342         .long 0x212     @ Map first page for exceptions (Kernel RO, Execute)
 343         .rept 16-1-2
 344                 .long 0
 345         .endr
 346         .long gUsertextPhysStart + 0x22 @ User .text (User RO, Kernel RW, because both is COW)
 347         .long 0
 348
 349 .section .padata
 350 stack:
 351         .space MM_KSTACK_SIZE, 0        @ Original kernel stack
 352
 353 // vim: ts=8, ft=armv7
 354