KernelLand/Kernel/arch/armv7/start.S

   1
   2 #include "include/assembly.h"
   3 #include "include/options.h"
   4
   5 @
   6 @ Exception defs taken from ARM DDI 0406B
   7 @
   8 .section .init
   9 interrupt_vector_table:
  10 ivt_reset:      b _start        @ 0x00 Reset
  11 ivt_undef:      b Undef_Handler @ 0x04 #UD
  12 ivt_svc:        b SVC_Handler   @ 0x08 SVC (used to be called SWI)
  13 ivt_prefetch:   b PrefetchAbort @ 0x0C Prefetch abort
  14 ivt_data:       b DataAbort     @ 0x10 Data abort
  15 ivt_unused:     b .             @ 0x14 Not Used
  16 ivt_irq:        b IRQHandler    @ 0x18 IRQ
  17 ivt_fiq:        b .             @ 0x1C FIQ (Fast interrupt)
  18
  19 .globl _start
  20 _start:
  21         ldr r2, =UART0_PADDR
  22         mov r1, #'A'
  23         str r1, [r2]
  24
  25         ldr r0, =kernel_table0-KERNEL_BASE
  26         mcr p15, 0, r0, c2, c0, 1       @ Set TTBR1 to r0
  27         mcr p15, 0, r0, c2, c0, 0       @ Set TTBR0 to r0 too (for identity)
  28
  29         mov r1, #'c'
  30         str r1, [r2]
  31
  32         mov r0, #1
  33         mcr p15, 0, r0, c2, c0, 2       @ Set TTCR to 1 (50/50 split)
  34
  35         mov r1, #'e'
  36         str r1, [r2]
  37
  38         mov r0, #3
  39         mcr p15, 0, r0, c3, c0, 0       @ Set Domain 0 to Manager
  40
  41         mov r1, #'s'
  42         str r1, [r2]
  43
  44         @ Enable VMSA
  45         mrc p15, 0, r0, c1, c0, 0
  46         orr r0, r0, #1
  47         orr r0, r0, #1 << 23
  48         mcr p15, 0, r0, c1, c0, 0
  49
  50         @ HACK: Set ASID to non zero
  51         mov r0, #1
  52         MCR p15,0,r0,c13,c0,1
  53
  54         ldr r2, =0xF1000000
  55         mov r1, #'s'
  56         str r1, [r2]
  57
  58         @ Enable access faults on domains 0 & 1
  59         mov r0, #0x55   @ 01010101b
  60         mcr p15, 0, r0, c3, c0, 0
  61
  62         mov r1, #'2'
  63         str r1, [r2]
  64
  65         @
  66         @ Check for security extensions
  67         @
  68         mrc p15, 0, r0, c0, c1, 1
  69         and r0, #0xF0
  70         @ - Present
  71         ldrne r0,=KERNEL_BASE
  72         mcrne p15, 0, r0, c12, c0, 0    @ Set the VBAR (brings exceptions into high memory)
  73         @ - Absent
  74         mrceq p15, 0, r0, c1, c0, 0     @ Set SCTLR.V
  75         orreq r0, #0x2000
  76         mcreq p15, 0, r0, c1, c0, 0
  77
  78         mov r1, #'-'
  79         str r1, [r2]
  80
  81         @ Prepare for interrupts
  82         cps #18 @ IRQ Mode
  83         ldr sp, =irqstack+0x1000        @ Set up stack
  84         cps #23 @ Abort Mode
  85         ldr sp, =abortstack+0x1000
  86         cps #19
  87
  88         mov r1, #'a'
  89         str r1, [r2]
  90         mov r1, #'r'
  91         str r1, [r2]
  92         mov r1, #'m'
  93         str r1, [r2]
  94         mov r1, #13
  95         str r1, [r2]
  96         mov r1, #10
  97         str r1, [r2]
  98
  99 .extern bss_start
 100 .extern bss_size_div_4
 101 .zero_bss:
 102         ldr r0, =bss_start
 103         ldr r1, =bss_end
 104         mov r3, #0
 105 .zero_bss_loop:
 106         str r3, [r0],#4
 107         cmp r0, r1
 108         bls .zero_bss_loop
 109
 110 .goto_c:
 111         ldr sp, =0x80000000-8   @ Set up stack (top of user range)
 112         ldr r0, =kmain
 113         mov pc, r0
 114 1:      b 1b    @ Infinite loop
 115
 116 .comm irqstack, 0x1000  @ ; 4KiB Stack
 117 .comm abortstack, 0x1000        @ ; 4KiB Stack
 118
 119 .extern SyscallHandler
 120 SVC_Handler:
 121 @       sub lr, #4
 122         srsdb sp!, #19  @ Save state to stack
 123         cpsie ifa, #19  @ Ensure we're in supervisor with interrupts enabled (should already be there)
 124         push {r0-r12}
 125
 126         ldr r4, [lr,#-4]
 127         mvn r5, #0xFF000000
 128         and r4, r5
 129
 130         tst r4, #0x1000
 131         bne .arm_specifics
 132
 133         push {r4}
 134
 135         mov r0, sp
 136         ldr r4, =SyscallHandler
 137         blx r4
 138
 139 @       ldr r0, =csSyscallPrintRetAddr
 140 @       ldr r1, [sp,#9*4+5*4]
 141 @       ldr r4, =Log
 142 @       blx r4
 143
 144         pop {r2}        @ errno
 145         pop {r0,r1}     @ Ret/RetHi
 146         add sp, #2*4    @ Saved r2/r3
 147
 148         pop {r4-r12}
 149         rfeia sp!       @ Pop state (actually RFEFD)
 150 .arm_specifics:
 151         and r4, #0xFF
 152         mov r0, r4      @ Number
 153         mov r1, sp      @ Arguments
 154
 155         ldr r4, =ARMv7_int_HandleSyscalls
 156         blx r4
 157
 158         add sp, #4*4
 159         pop {r4-r12}
 160         rfeia sp!
 161
 162
 163 .globl gpIRQHandler
 164 gpIRQHandler:   .long   0
 165 IRQ_saved_sp:   .long   0
 166 IRQ_saved_lr:   .long   0
 167 .globl IRQHandler
 168 IRQHandler:
 169         sub lr, #4      @ Adjust LR to the correct value
 170         srsdb sp!, #19  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 171         cps #19
 172
 173         PUSH_GPRS
 174
 175 @       ldr r0, =csIRQ_Tag
 176 @       ldr r1, =csIRQ_Fmt
 177 @       ldr r4, =Log_Debug
 178 @       blx r4
 179
 180         @ Call the registered handler
 181         ldr r0, gpIRQHandler
 182         blx r0
 183
 184         @ Restore CPU state
 185         POP_GPRS
 186         cpsie i
 187         rfeia sp!       @ Pop state (actually RFEFD)
 188         bx lr
 189
 190 .globl DataAbort
 191 DataAbort:
 192         sub lr, #8      @ Adjust LR to the correct value
 193         srsdb sp!, #23  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 194 @       cpsid ifa, #19
 195         PUSH_GPRS
 196
 197         mov r3, #0      @ not a prefetch abort
 198         mrc p15, 0, r2, c5, c0, 0       @ Read DFSR (Data Fault Status Register) to R2
 199         mrc p15, 0, r1, c6, c0, 0       @ Read DFAR (Data Fault Address Register) into R1
 200         mov r0, lr      @ PC
 201         ldr r4, =MM_PageFault
 202         blx r4
 203
 204         POP_GPRS
 205         rfeia sp!       @ Pop state (actually RFEFD)
 206
 207 .globl PrefetchAbort
 208 PrefetchAbort:
 209         sub lr, #4      @ Adjust LR to the correct value
 210         srsdb sp!, #23  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 211 @       cpsid ifa, #19
 212         PUSH_GPRS
 213
 214         ldr r0, =csAbort_Tag
 215         ldr r1, =csPrefetchAbort_Fmt
 216 #       mov r2, lr
 217         mrc p15, 0, r2, c6, c0, 2       @ Read IFAR (Instruction Fault Address Register) into R3
 218         mrc p15, 0, r3, c5, c0, 1       @ Read IFSR (Instruction Fault Status Register) into R3
 219         ldr r5, =Log_Error
 220         blx r5
 221
 222 .loop:
 223         wfi
 224         b .loop
 225 .globl Undef_Handler
 226 Undef_Handler:
 227         wfi
 228         b Undef_Handler
 229
 230
 231
 232 .section .rodata
 233 csIRQ_Tag:
 234 csAbort_Tag:
 235         .asciz "ARMv7"
 236 csIRQ_Fmt:
 237         .asciz "IRQ"
 238 csDataAbort_Fmt:
 239         .asciz "Data Abort - %p accessed %p, DFSR=%x Unk:%x Unk:%x"
 240 csPrefetchAbort_Fmt:
 241         .asciz "Prefetch Abort at %p, IFSR=%x"
 242 csSyscallPrintRetAddr:
 243         .asciz "Syscall ret to %p"
 244
 245 .section .padata
 246 .globl kernel_table0
 247
 248 kernel_table0:
 249         .long 0x00000402        @ Identity map the first 1 MiB
 250         .rept 0x7FC - 1
 251                 .long 0
 252         .endr
 253         .long user_table1_map + 0x000 - KERNEL_BASE + 1 @ 0x7FC00000
 254         .long user_table1_map + 0x400 - KERNEL_BASE + 1 @ 0x7FD00000
 255         .long user_table1_map + 0x800 - KERNEL_BASE + 1 @ KStacks
 256         .long user_table1_map + 0xC00 - KERNEL_BASE + 1
 257         @ 0x80000000 - User/Kernel split
 258         .long 0x00000402        @ Map first 4 MiB to 2GiB (KRW only)
 259         .long 0x00100402        @
 260         .long 0x00200402        @
 261         .long 0x00300402        @
 262         .rept 0xF00 - 0x800 - 4
 263                 .long 0
 264         .endr
 265 #if PCI_PADDR
 266         .long PCI_PADDR +  0*(1 << 20) + 0x402  @ Map PCI config space
 267         .long PCI_PADDR +  1*(1 << 20) + 0x402
 268         .long PCI_PADDR +  2*(1 << 20) + 0x402
 269         .long PCI_PADDR +  3*(1 << 20) + 0x402
 270         .long PCI_PADDR +  4*(1 << 20) + 0x402
 271         .long PCI_PADDR +  5*(1 << 20) + 0x402
 272         .long PCI_PADDR +  6*(1 << 20) + 0x402
 273         .long PCI_PADDR +  7*(1 << 20) + 0x402
 274         .long PCI_PADDR +  8*(1 << 20) + 0x402
 275         .long PCI_PADDR +  9*(1 << 20) + 0x402
 276         .long PCI_PADDR + 10*(1 << 20) + 0x402
 277         .long PCI_PADDR + 11*(1 << 20) + 0x402
 278         .long PCI_PADDR + 12*(1 << 20) + 0x402
 279         .long PCI_PADDR + 13*(1 << 20) + 0x402
 280         .long PCI_PADDR + 14*(1 << 20) + 0x402
 281         .long PCI_PADDR + 15*(1 << 20) + 0x402
 282 #else
 283         .rept 16
 284                 .long 0
 285         .endr
 286 #endif
 287         .long hwmap_table_0 + 0x000 - KERNEL_BASE + 1
 288         .long hwmap_table_0 + 0x400 - KERNEL_BASE + 1
 289         .long hwmap_table_0 + 0x800 - KERNEL_BASE + 1
 290         .long hwmap_table_0 + 0xC00 - KERNEL_BASE + 1
 291         .rept 0xFF8 - 0xF00 - 16 - 4
 292                 .long 0
 293         .endr
 294         @ Page fractals
 295         .long kernel_table1_map + 0x000 - KERNEL_BASE + 1
 296         .long kernel_table1_map + 0x400 - KERNEL_BASE + 1
 297         .long kernel_table1_map + 0x800 - KERNEL_BASE + 1
 298         .long kernel_table1_map + 0xC00 - KERNEL_BASE + 1
 299         .long kernel_exception_map + 0x000 - KERNEL_BASE + 1
 300         .long kernel_exception_map + 0x400 - KERNEL_BASE + 1
 301         .long kernel_exception_map + 0x800 - KERNEL_BASE + 1
 302         .long kernel_exception_map + 0xC00 - KERNEL_BASE + 1
 303
 304 @ PID0 user table
 305 .globl user_table1_map
 306 @ User table1 data table (only the first half is needed)
 307 @ - Abused to provide kernel stacks in the unused half of the table
 308 user_table1_map:        @ Size = 4KiB (only 2KiB used)
 309         .rept 0x800/4-1
 310                 .long 0
 311         .endr
 312         .long user_table1_map - KERNEL_BASE + 0x13      @ ...1FF000 = 0x7FDFF000
 313         @ Kernel stack zone
 314         .long kernel_table0 + 0x0000 - KERNEL_BASE + 0x13       @ ...200000 = 0x7FE00000
 315         .long kernel_table0 + 0x1000 - KERNEL_BASE + 0x13       @ ...201000 = 0x7FE01000
 316         .rept (0x800/4)-(MM_KSTACK_SIZE/0x1000)-2
 317                 .long 0
 318         .endr
 319         #if MM_KSTACK_SIZE != 0x2000
 320         #error Kernel stack size not changed in start.S
 321         #endif
 322         .long stack + 0x0000 - KERNEL_BASE + 0x13       @ Kernel Stack
 323         .long stack + 0x1000 - KERNEL_BASE + 0x13       @
 324
 325 .globl kernel_table1_map
 326 kernel_table1_map:      @ Size = 4KiB
 327         .rept (0xF00+16)/4
 328                 .long 0
 329         .endr
 330         .long hwmap_table_0 - KERNEL_BASE + 0x13
 331         .rept 0xFF8/4 - (0xF00+16)/4 - 1
 332                 .long 0
 333         .endr
 334         .long kernel_table1_map - KERNEL_BASE + 0x13
 335         .long kernel_exception_map - KERNEL_BASE + 0x13
 336
 337 @ Hardware mappings
 338 .globl hwmap_table_0
 339 hwmap_table_0:
 340         .long UART0_PADDR + 0x13        @ UART0
 341         .rept 1024 - 1
 342                 .long 0
 343         .endr
 344 .globl kernel_exception_map
 345 kernel_exception_map:
 346         @ Padding
 347         .rept 1024-256
 348                 .long 0
 349         .endr
 350         @ Align to nearly the end
 351         .rept 256-16
 352                 .long   0
 353         .endr
 354         .long 0x212     @ Map first page for exceptions (Kernel RO, Execute)
 355         .rept 16-1-2
 356                 .long 0
 357         .endr
 358         .long gUsertextPhysStart + 0x22 @ User .text (User RO, Kernel RW, because both is COW)
 359         .long 0
 360
 361 .section .padata
 362 stack:
 363         .space MM_KSTACK_SIZE, 0        @ Original kernel stack
 364
 365 // vim: ts=8 ft=armv7
 366