KernelLand/Kernel/arch/armv7/start.S

   1
   2 #include "include/assembly.h"
   3 #include "include/options.h"
   4
   5 @
   6 @ Exception defs taken from ARM DDI 0406B
   7 @
   8 .section .init
   9 interrupt_vector_table:
  10 ivt_reset:      b _start        @ 0x00 Reset
  11 ivt_undef:      b Undef_Handler @ 0x04 #UD
  12 ivt_svc:        b SVC_Handler   @ 0x08 SVC (used to be called SWI)
  13 ivt_prefetch:   b PrefetchAbort @ 0x0C Prefetch abort
  14 ivt_data:       b DataAbort     @ 0x10 Data abort
  15 ivt_unused:     b .             @ 0x14 Not Used
  16 ivt_irq:        b IRQHandler    @ 0x18 IRQ
  17 ivt_fiq:        b .             @ 0x1C FIQ (Fast interrupt)
  18
  19 .globl _start
  20 _start:
  21         ldr r2, =UART0_PADDR
  22         mov r1, #'A'
  23         str r1, [r2]
  24
  25         ldr r0, =kernel_table0-KERNEL_BASE
  26         mcr p15, 0, r0, c2, c0, 1       @ Set TTBR1 to r0
  27         mcr p15, 0, r0, c2, c0, 0       @ Set TTBR0 to r0 too (for identity)
  28
  29         mov r1, #'c'
  30         str r1, [r2]
  31
  32         mov r0, #1
  33         mcr p15, 0, r0, c2, c0, 2       @ Set TTCR to 1 (50/50 split)
  34
  35         mov r1, #'e'
  36         str r1, [r2]
  37
  38         mov r0, #3
  39         mcr p15, 0, r0, c3, c0, 0       @ Set Domain 0 to Manager
  40
  41         mov r1, #'s'
  42         str r1, [r2]
  43
  44         @ Enable VMSA
  45         mrc p15, 0, r0, c1, c0, 0
  46         orr r0, r0, #1
  47         orr r0, r0, #1 << 23
  48         mcr p15, 0, r0, c1, c0, 0
  49
  50         @ HACK: Set ASID to non zero
  51         mov r0, #1
  52         MCR p15,0,r0,c13,c0,1
  53
  54         ldr r2, =0xF1000000
  55         mov r1, #'s'
  56         str r1, [r2]
  57
  58         @ Enable access faults on domains 0 & 1
  59         mov r0, #0x55   @ 01010101b
  60         mcr p15, 0, r0, c3, c0, 0
  61
  62         mov r1, #'2'
  63         str r1, [r2]
  64
  65         @
  66         @ Check for security extensions
  67         @
  68         mrc p15, 0, r0, c0, c1, 1
  69         and r0, #0xF0
  70         beq .no_sec_ext
  71         @ - Present
  72         ldr r0,=KERNEL_BASE
  73         mcr p15, 0, r0, c12, c0, 0      @ Set the VBAR (brings exceptions into high memory)
  74         b .exceptions_vectored
  75 .no_sec_ext:
  76         @ - Absent
  77         mrc p15, 0, r0, c1, c0, 0       @ Set SCTLR.V
  78         orr r0, #0x2000
  79         mcr p15, 0, r0, c1, c0, 0
  80 .exceptions_vectored:
  81
  82         mov r1, #'-'
  83         str r1, [r2]
  84
  85         @ Prepare for interrupts
  86         cps #18 @ IRQ Mode
  87         ldr sp, =irqstack+0x1000        @ Set up stack
  88         cps #23 @ Abort Mode
  89         ldr sp, =abortstack+0x1000
  90         cps #19
  91
  92         mov r1, #'a'
  93         str r1, [r2]
  94         mov r1, #'r'
  95         str r1, [r2]
  96         mov r1, #'m'
  97         str r1, [r2]
  98         mov r1, #13
  99         str r1, [r2]
 100         mov r1, #10
 101         str r1, [r2]
 102
 103 .extern bss_start
 104 .extern bss_size_div_4
 105 .zero_bss:
 106         ldr r0, =bss_start
 107         ldr r1, =bss_end
 108         mov r3, #0
 109 .zero_bss_loop:
 110         str r3, [r0],#4
 111         cmp r0, r1
 112         bls .zero_bss_loop
 113
 114 .goto_c:
 115         ldr sp, =0x80000000-8   @ Set up stack (top of user range)
 116         ldr r0, =kmain
 117         mov pc, r0
 118 1:      b 1b    @ Infinite loop
 119
 120 .comm irqstack, 0x1000  @ ; 4KiB Stack
 121 .comm abortstack, 0x1000        @ ; 4KiB Stack
 122
 123 .extern SyscallHandler
 124 SVC_Handler:
 125 @       sub lr, #4
 126         srsdb sp!, #19  @ Save state to stack
 127         cpsie ifa, #19  @ Ensure we're in supervisor with interrupts enabled (should already be there)
 128         push {r0-r12}
 129
 130         ldr r4, [lr,#-4]
 131         mvn r5, #0xFF000000
 132         and r4, r5
 133
 134         tst r4, #0x1000
 135         bne .arm_specifics
 136
 137         push {r4}
 138
 139         mov r0, sp
 140         ldr r4, =SyscallHandler
 141         blx r4
 142
 143 @       ldr r0, =csSyscallPrintRetAddr
 144 @       ldr r1, [sp,#9*4+5*4]
 145 @       ldr r4, =Log
 146 @       blx r4
 147
 148         pop {r2}        @ errno
 149         pop {r0,r1}     @ Ret/RetHi
 150         add sp, #2*4    @ Saved r2/r3
 151
 152         pop {r4-r12}
 153         rfeia sp!       @ Pop state (actually RFEFD)
 154 .arm_specifics:
 155         and r4, #0xFF
 156         mov r0, r4      @ Number
 157         mov r1, sp      @ Arguments
 158
 159         ldr r4, =ARMv7_int_HandleSyscalls
 160         blx r4
 161
 162         add sp, #4*4
 163         pop {r4-r12}
 164         rfeia sp!
 165
 166
 167 .globl gpIRQHandler
 168 gpIRQHandler:   .long   0
 169 IRQ_saved_sp:   .long   0
 170 IRQ_saved_lr:   .long   0
 171 .globl IRQHandler
 172 IRQHandler:
 173         sub lr, #4      @ Adjust LR to the correct value
 174         srsdb sp!, #19  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 175         cps #19
 176
 177         PUSH_GPRS
 178
 179 @       ldr r0, =csIRQ_Tag
 180 @       ldr r1, =csIRQ_Fmt
 181 @       ldr r4, =Log_Debug
 182 @       blx r4
 183
 184         @ Call the registered handler
 185         ldr r0, gpIRQHandler
 186         blx r0
 187
 188         @ Restore CPU state
 189         POP_GPRS
 190         cpsie i
 191         rfeia sp!       @ Pop state (actually RFEFD)
 192         bx lr
 193
 194 .globl DataAbort
 195 DataAbort:
 196         sub lr, #8      @ Adjust LR to the correct value
 197         srsdb sp!, #23  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 198 @       cpsid ifa, #19
 199         PUSH_GPRS
 200
 201         @ Get the user's LR value (and push to stack)
 202         cps #31 @ Go to system mode
 203         mov r1, lr
 204         cps #19 @ Go to supervisor
 205         mov r0, lr
 206         cps #23 @ back to exception
 207         push {r0,r1}
 208
 209         mov r3, #0      @ not a prefetch abort
 210         mrc p15, 0, r2, c5, c0, 0       @ Read DFSR (Data Fault Status Register) to R2
 211         mrc p15, 0, r1, c6, c0, 0       @ Read DFAR (Data Fault Address Register) into R1
 212         mov r0, lr      @ PC
 213         ldr r4, =MM_PageFault
 214         blx r4
 215         add sp, #8      @ Undo push of the user/system LR
 216
 217         POP_GPRS
 218         rfeia sp!       @ Pop state (actually RFEFD)
 219
 220 .globl PrefetchAbort
 221 PrefetchAbort:
 222         sub lr, #4      @ Adjust LR to the correct value
 223         srsdb sp!, #23  @ Switch to supervisor mode (DDI0406B D1.6.5) (actually SRSFD)
 224 @       cpsid ifa, #19
 225         PUSH_GPRS
 226
 227
 228         @ Get the user's LR value (and push to stack)
 229         cps #31 @ Go to system mode
 230         mov r0, lr
 231         cps #23 @ back to supervisor
 232         push {r0}
 233
 234         mrc p15, 0, r2, c5, c0, 1       @ Read IFSR (Instruction Fault Status Register) into R3
 235         mrc p15, 0, r1, c6, c0, 2       @ Read IFAR (Instruction Fault Address Register) into R3
 236         mov r0, r1
 237         mov r3, #1      @ IS a prefetch abort
 238         ldr r4, =MM_PageFault
 239         blx r4
 240         add sp, #4      @ Undo push of the user LR
 241
 242         POP_GPRS
 243         rfeia sp!       @ Pop state (actually RFEFD)
 244
 245 .globl Undef_Handler
 246 Undef_Handler:
 247         wfi
 248         b Undef_Handler
 249
 250
 251
 252 .section .rodata
 253 csIRQ_Tag:
 254 csAbort_Tag:
 255         .asciz "ARMv7"
 256 csIRQ_Fmt:
 257         .asciz "IRQ"
 258 csDataAbort_Fmt:
 259         .asciz "Data Abort - %p accessed %p, DFSR=%x Unk:%x Unk:%x"
 260 csPrefetchAbort_Fmt:
 261         .asciz "Prefetch Abort at %p, IFSR=%x, UserLR:0x%x"
 262 csSyscallPrintRetAddr:
 263         .asciz "Syscall ret to %p"
 264
 265 .section .padata
 266 .globl kernel_table0
 267
 268 kernel_table0:
 269         .long 0x00000402        @ Identity map the first 1 MiB
 270         .rept 0x7FC - 1
 271                 .long 0
 272         .endr
 273         .long user_table1_map + 0x000 - KERNEL_BASE + 1 @ 0x7FC00000
 274         .long user_table1_map + 0x400 - KERNEL_BASE + 1 @ 0x7FD00000
 275         .long user_table1_map + 0x800 - KERNEL_BASE + 1 @ KStacks
 276         .long user_table1_map + 0xC00 - KERNEL_BASE + 1
 277         @ 0x80000000 - User/Kernel split
 278         .long 0x00000402        @ Map first 4 MiB to 2GiB (KRW only)
 279         .long 0x00100402        @
 280         .long 0x00200402        @
 281         .long 0x00300402        @
 282         .rept 0xF00 - 0x800 - 4
 283                 .long 0
 284         .endr
 285 #if PCI_PADDR
 286         .long PCI_PADDR +  0*(1 << 20) + 0x402  @ Map PCI config space
 287         .long PCI_PADDR +  1*(1 << 20) + 0x402
 288         .long PCI_PADDR +  2*(1 << 20) + 0x402
 289         .long PCI_PADDR +  3*(1 << 20) + 0x402
 290         .long PCI_PADDR +  4*(1 << 20) + 0x402
 291         .long PCI_PADDR +  5*(1 << 20) + 0x402
 292         .long PCI_PADDR +  6*(1 << 20) + 0x402
 293         .long PCI_PADDR +  7*(1 << 20) + 0x402
 294         .long PCI_PADDR +  8*(1 << 20) + 0x402
 295         .long PCI_PADDR +  9*(1 << 20) + 0x402
 296         .long PCI_PADDR + 10*(1 << 20) + 0x402
 297         .long PCI_PADDR + 11*(1 << 20) + 0x402
 298         .long PCI_PADDR + 12*(1 << 20) + 0x402
 299         .long PCI_PADDR + 13*(1 << 20) + 0x402
 300         .long PCI_PADDR + 14*(1 << 20) + 0x402
 301         .long PCI_PADDR + 15*(1 << 20) + 0x402
 302 #else
 303         .rept 16
 304                 .long 0
 305         .endr
 306 #endif
 307         .long hwmap_table_0 + 0x000 - KERNEL_BASE + 1
 308         .long hwmap_table_0 + 0x400 - KERNEL_BASE + 1
 309         .long hwmap_table_0 + 0x800 - KERNEL_BASE + 1
 310         .long hwmap_table_0 + 0xC00 - KERNEL_BASE + 1
 311         .rept 0xFF8 - 0xF00 - 16 - 4
 312                 .long 0
 313         .endr
 314         @ Page fractals
 315         .long kernel_table1_map + 0x000 - KERNEL_BASE + 1
 316         .long kernel_table1_map + 0x400 - KERNEL_BASE + 1
 317         .long kernel_table1_map + 0x800 - KERNEL_BASE + 1
 318         .long kernel_table1_map + 0xC00 - KERNEL_BASE + 1
 319         .long kernel_exception_map + 0x000 - KERNEL_BASE + 1
 320         .long kernel_exception_map + 0x400 - KERNEL_BASE + 1
 321         .long kernel_exception_map + 0x800 - KERNEL_BASE + 1
 322         .long kernel_exception_map + 0xC00 - KERNEL_BASE + 1
 323
 324 @ PID0 user table
 325 .globl user_table1_map
 326 @ User table1 data table (only the first half is needed)
 327 @ - Abused to provide kernel stacks in the unused half of the table
 328 user_table1_map:        @ Size = 4KiB (only 2KiB used)
 329         .rept 0x800/4-1
 330                 .long 0
 331         .endr
 332         .long user_table1_map - KERNEL_BASE + 0x13      @ ...1FF000 = 0x7FDFF000
 333         @ Kernel stack zone
 334         .long kernel_table0 + 0x0000 - KERNEL_BASE + 0x13       @ ...200000 = 0x7FE00000
 335         .long kernel_table0 + 0x1000 - KERNEL_BASE + 0x13       @ ...201000 = 0x7FE01000
 336         .rept (0x800/4)-(MM_KSTACK_SIZE/0x1000)-2
 337                 .long 0
 338         .endr
 339         #if MM_KSTACK_SIZE != 0x2000
 340         #error Kernel stack size not changed in start.S
 341         #endif
 342         .long stack + 0x0000 - KERNEL_BASE + 0x13       @ Kernel Stack
 343         .long stack + 0x1000 - KERNEL_BASE + 0x13       @
 344
 345 .globl kernel_table1_map
 346 kernel_table1_map:      @ Size = 4KiB
 347         .rept (0xF00+16)/4
 348                 .long 0
 349         .endr
 350         .long hwmap_table_0 - KERNEL_BASE + 0x13
 351         .rept 0xFF8/4 - (0xF00+16)/4 - 1
 352                 .long 0
 353         .endr
 354         .long kernel_table1_map - KERNEL_BASE + 0x13
 355         .long kernel_exception_map - KERNEL_BASE + 0x13
 356
 357 @ Hardware mappings
 358 .globl hwmap_table_0
 359 hwmap_table_0:
 360         .long UART0_PADDR + 0x13        @ UART0
 361         .rept 1024 - 1
 362                 .long 0
 363         .endr
 364 .globl kernel_exception_map
 365 kernel_exception_map:
 366         @ Padding
 367         .rept 1024-256
 368                 .long 0
 369         .endr
 370         @ Align to nearly the end
 371         .rept 256-16
 372                 .long   0
 373         .endr
 374         .long 0x212     @ Map first page for exceptions (Kernel RO, Execute)
 375         .rept 16-1-2
 376                 .long 0
 377         .endr
 378         .long gUsertextPhysStart + 0x22 @ User .text (User RO, Kernel RW, because both is COW)
 379         .long 0
 380
 381 .section .padata
 382 stack:
 383         .space MM_KSTACK_SIZE, 0        @ Original kernel stack
 384
 385 // vim: ts=8 ft=armv7
 386